sys-kernel/gentoo-kernel-bin: bump to 5.12.11 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 116 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 5dd41d42c5a3..7adc00a90ee6 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -29,6 +29,7 @@ DIST gentoo-kernel-5.12.10-1.amd64.xpak 66370289 BLAKE2B 74f9046d711902b5cb650c0
 DIST gentoo-kernel-5.12.10-1.arm64.xpak 62567249 BLAKE2B e20ff0b59f3f0781cbb7d1a2eb290e46cdb8fc0f4aa189bb70f7ad5d02b54a5a30bdb3d91c779bfdb04daf01efe5c85376c4a3faa52cead80743aae588993e26 SHA512 ee5daf6872844476018ddab8445e3dbd25d1585a8cd2b6195028b8f8690cb262befcfdef3e0267a422f30c4ca0036dd6c985331cbacdc0c8e79f9c7c9755f4ba
 DIST gentoo-kernel-5.12.10-1.x86.xpak 58113734 BLAKE2B 093fc8ae00efefb2eb38cd0ce145f16e046be2f5110ad18d957ae122b97a1d4a6e6d8cce4c42f53ece1dabe9ebd99640c922686a8a00f7186bdc5f8b82f44144 SHA512 5c58a7277e1c3b1017ead2584dd6c768b2b4476f0da0c3dbd28facec64c1f37a3db9119d869720f6f63e3e1c53ffb8d69efef8f5008e0a71f8f55098d2ce9d83
 DIST gentoo-kernel-5.12.11-1.amd64.xpak 66335668 BLAKE2B eb8860e2dc03a9b8b0b350ffd84d2fac5a00ef144b57a3bb2623f1d7cf46c965509c026e92c706b6ef4c3fe32ed8c48bb525b434e928eb6ff8702bdf2744b598 SHA512 e6ebde7de77315b1e0f85e6e2e8b76caec0218bffcb9e9e3f563abb6c792c2fdd62e5c30e6b25e1c9b2ec4d095e7a02479293a0f7e7b6ed6a258b6aebe102d85
+DIST gentoo-kernel-5.12.11-1.arm64.xpak 60224274 BLAKE2B 2a3d2b3a5e1ae0f561c1fd41297f06f13ef7c68e6f8e3c8192253b888f8f738e7adcb98dfd5b4e246e951af7a5f1c2ed19fd2b6f423701c2651ccb1ffd5a0dd6 SHA512 b9d494dd138dfde68a71605f61b2f8d28236bcd0c836950c417c82c26335bc238c12cc0e09b752db12b9bfd5553eef56169f3809af35021756888e39cddf7029
 DIST gentoo-kernel-5.12.11-1.x86.xpak 58070750 BLAKE2B 9e5c5e03bde9f2c707c9914d620d9c12fc148088b57ea89cf06922c3111058979ef4a9b2a6332a29b7a563cdabaf9c350da5e7048ad2995cd4274f8daa0fa895 SHA512 95e96a56c9ad5820545e3f085ababbe12daf9dd4582088f86a0a33dca45694c9290d1b65f13097b2e0729cf94a06b3e99500561c868bed3dc45d956970c03f71
 DIST gentoo-kernel-5.4.120-1.amd64.xpak 61385726 BLAKE2B 4eda28bcfaaeb8caaa0d74c6fb37b203528ccd9853c775bcd40dc9f4698edc282a5c70602b42945b98840b1ea3d6b0d620b7726c65c83c16363e1c7542822cc1 SHA512 c36c7c5f309dea87df6af0567929f7fe09656ac49e33fd7edca62522aa45656e53d717dca5a9702b246446f25d7c3249ef0fdae8554f71cedf90339bc8b620eb
 DIST gentoo-kernel-5.4.120-1.arm64.xpak 56380077 BLAKE2B d9d0a98d00b17925c852b75875ba4eb373624cd1fc35df60aa50796e81facb5067146f3008313b5776aae7b251ae6559118cb36f1480813073341dfa37de01ac SHA512 c207f79b59ae38ab58a2f7341c8d21e3fc388eb949417a033d4dfd9fb0a7acdcac4a1d5ce8528708e7a2dfba1b241f0cf03235b5c2fb9dd1c930a36a8bebd2f5
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.11-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.11-r1.ebuild
new file mode 100644
index 000000000000..9cc54d1c175f
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.11-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}