summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndrew Savchenko <bircoph@gentoo.org>2018-11-11 18:08:42 +0300
committerAndrew Savchenko <bircoph@gentoo.org>2018-11-11 18:09:30 +0300
commitf9e3aebba785f595c12cb62db62985b609160b28 (patch)
tree914e337cab363ff790d91d8f456c75cb3756c1fa /sys-power/suspend
parentmedia-sound/mpd: restrict meson version up to a minor release (diff)
downloadgentoo-f9e3aebba785f595c12cb62db62985b609160b28.tar.gz
gentoo-f9e3aebba785f595c12cb62db62985b609160b28.tar.bz2
gentoo-f9e3aebba785f595c12cb62db62985b609160b28.zip
sys-power/suspend: remove fbsplash support
- Drop USE=fbsplash due to media-gfx/splashutils tree cleaning. - Update to EAPI 7. Closes: https://bugs.gentoo.org/650084 Signed-off-by: Andrew Savchenko <bircoph@gentoo.org> Package-Manager: Portage-2.3.51, Repoman-2.3.11
Diffstat (limited to 'sys-power/suspend')
-rw-r--r--sys-power/suspend/suspend-1.0_p20150810-r1.ebuild59
1 files changed, 59 insertions, 0 deletions
diff --git a/sys-power/suspend/suspend-1.0_p20150810-r1.ebuild b/sys-power/suspend/suspend-1.0_p20150810-r1.ebuild
new file mode 100644
index 00000000000..eedae70926c
--- /dev/null
+++ b/sys-power/suspend/suspend-1.0_p20150810-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+BASE_PV="1.0_p20120915"
+
+DESCRIPTION="Userspace Software Suspend and S2Ram"
+HOMEPAGE="http://suspend.sourceforge.net/"
+SRC_URI="https://dev.gentoo.org/~bircoph/distfiles/${PN}-${BASE_PV}.tar.xz
+ https://dev.gentoo.org/~bircoph/patches/${P}.patch.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="crypt +lzo threads"
+
+RDEPEND="
+ dev-libs/libx86
+ >=sys-apps/pciutils-2.2.4
+ crypt? (
+ >=dev-libs/libgcrypt-1.6.3:0[static-libs]
+ dev-libs/libgpg-error[static-libs] )
+ lzo? ( >=dev-libs/lzo-2[static-libs] ) "
+DEPEND="${RDEPEND}"
+BDEPEND="
+ >=dev-lang/perl-5.10
+ virtual/pkgconfig"
+
+S="${WORKDIR}/${PN}"
+
+PATCHES=( "${WORKDIR}/${P}.patch" )
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ econf \
+ --docdir="/usr/share/doc/${PF}" \
+ --disable-fbsplash \
+ $(use_enable crypt encrypt) \
+ $(use_enable lzo compress) \
+ $(use_enable threads)
+}
+
+src_install() {
+ dodir etc
+ emake DESTDIR="${D}" install
+ rm "${D}/usr/share/doc/${PF}"/COPYING* || die
+}
+
+pkg_postinst() {
+ elog "In order to make this package work with genkernel see:"
+ elog "https://bugs.gentoo.org/show_bug.cgi?id=156445"
+}