summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorRobin H. Johnson <robbat2@gentoo.org>2015-08-08 13:49:04 -0700
committerRobin H. Johnson <robbat2@gentoo.org>2015-08-08 17:38:18 -0700
commit56bd759df1d0c750a065b8c845e93d5dfa6b549d (patch)
tree3f91093cdb475e565ae857f1c5a7fd339e2d781e /www-misc/monitorix/monitorix-3.5.1.ebuild
downloadgentoo-56bd759df1d0c750a065b8c845e93d5dfa6b549d.tar.gz
gentoo-56bd759df1d0c750a065b8c845e93d5dfa6b549d.tar.bz2
gentoo-56bd759df1d0c750a065b8c845e93d5dfa6b549d.zip
proj/gentoo: Initial commit
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
Diffstat (limited to 'www-misc/monitorix/monitorix-3.5.1.ebuild')
-rw-r--r--www-misc/monitorix/monitorix-3.5.1.ebuild96
1 files changed, 96 insertions, 0 deletions
diff --git a/www-misc/monitorix/monitorix-3.5.1.ebuild b/www-misc/monitorix/monitorix-3.5.1.ebuild
new file mode 100644
index 00000000000..b638a226b88
--- /dev/null
+++ b/www-misc/monitorix/monitorix-3.5.1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit eutils systemd user
+
+DESCRIPTION="A lightweight system monitoring tool"
+HOMEPAGE="http://www.${PN}.org/"
+SRC_URI="http://www.${PN}.org/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="apcupsd hddtemp httpd lm_sensors postfix"
+
+DEPEND="sys-apps/sed"
+RDEPEND="dev-perl/Config-General
+ dev-perl/DBI
+ dev-perl/HTTP-Server-Simple
+ dev-perl/IO-Socket-SSL
+ dev-perl/libwww-perl
+ dev-perl/MIME-Lite
+ dev-perl/XML-Simple
+ net-analyzer/rrdtool[perl]
+ dev-perl/CGI
+ apcupsd? ( sys-power/apcupsd )
+ hddtemp? ( app-admin/hddtemp )
+ httpd? ( virtual/httpd-cgi )
+ lm_sensors? ( sys-apps/lm_sensors )
+ postfix? ( net-mail/pflogsumm dev-perl/MailTools )"
+
+pkg_setup() {
+ enewgroup ${PN}
+ enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
+}
+
+src_prepare() {
+ # Put better Gentoo defaults in the configuration file.
+ sed -i "s|\(base_dir.*\)/usr/share/${PN}|\1/usr/share/${PN}/htdocs|" ${PN}.conf
+ sed -i "s|\(secure_log.*\)/var/log/secure|\1/var/log/auth.log|" ${PN}.conf
+ sed -i "s|nobody|${PN}|g" ${PN}.conf
+}
+
+src_install() {
+ dosbin ${PN}
+
+ newinitd "${FILESDIR}"/${P}.init ${PN}
+
+ insinto /etc/monitorix
+ doins ${PN}.conf
+
+ dodir /etc/${PN}/conf.d
+
+ insinto /etc/logrotate.d
+ newins docs/${PN}.logrotate ${PN}
+
+ dodoc Changes README{,.nginx} docs/${PN}.service docs/${PN}-{alert.sh,apache.conf,lighttpd.conf}
+ doman man/man5/${PN}.conf.5
+ doman man/man8/${PN}.8
+
+ insinto /var/lib/${PN}/www
+ doins logo_bot.png logo_top.png ${PN}ico.png
+
+ dodir /var/lib/${PN}/imgs
+ dosym /var/lib/${PN}/imgs /var/lib/${PN}/www/imgs
+
+ exeinto /var/lib/${PN}/www/cgi
+ doexe ${PN}.cgi
+
+ dodir /usr/lib/${PN}
+ exeinto /usr/lib/${PN}
+ doexe lib/*.pm
+
+ dodir /var/lib/${PN}/usage
+ insinto /var/lib/${PN}/reports
+ doins -r reports/*
+
+ systemd_dounit docs/${PN}.service
+}
+
+pkg_postinst() {
+ chown monitorix:monitorix /var/lib/${PN}/imgs
+
+ elog "WARNING: ${PN} has changed its config format twice, in versions"
+ elog "3.0.0 and 3.4.0; this format may be incompatible with your existing"
+ elog "config file. Please take care if upgrading from an old version."
+ elog ""
+
+ elog "${PN} includes its own web server as of version 3.0.0."
+ elog "For this reason, the dependency on the webapp framework"
+ elog "has been removed. If you wish to use your own web server,"
+ elog "the ${PN} web data can be found at:"
+ elog "/var/lib/${PN}/www/"
+}