summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichał Górny <mgorny@gentoo.org>2019-12-08 11:36:15 +0100
committerMichał Górny <mgorny@gentoo.org>2019-12-08 12:11:32 +0100
commit411652c688ed7a342cbb19302e641f3f6afd8ca9 (patch)
treec081d33657762a6721ccd65ef919927c51d762bf /www-plugins/lightspark
parentsys-auth/elogind: keyworded 241.4 for hppa, bug #681200 (diff)
downloadgentoo-411652c688ed7a342cbb19302e641f3f6afd8ca9.tar.gz
gentoo-411652c688ed7a342cbb19302e641f3f6afd8ca9.tar.bz2
gentoo-411652c688ed7a342cbb19302e641f3f6afd8ca9.zip
www-plugins/lightspark: Bump to 0.8.2
Closes: https://bugs.gentoo.org/695404 Signed-off-by: Michał Górny <mgorny@gentoo.org>
Diffstat (limited to 'www-plugins/lightspark')
-rw-r--r--www-plugins/lightspark/Manifest1
-rw-r--r--www-plugins/lightspark/lightspark-0.8.2.ebuild97
2 files changed, 98 insertions, 0 deletions
diff --git a/www-plugins/lightspark/Manifest b/www-plugins/lightspark/Manifest
index 0a5f1694be5..402d8381463 100644
--- a/www-plugins/lightspark/Manifest
+++ b/www-plugins/lightspark/Manifest
@@ -1 +1,2 @@
DIST lightspark-0.8.1.tar.gz 1899466 BLAKE2B d057deccc8ee03f16bfd384c9aee94ee70b7f6674bb0d46c2965f27868a2177c2985f791801975aab1608b4e59d9d40a51e327ec4b00e60eb6714f610b4c319f SHA512 ee9f02e4aa160d8e68cab743eddce5f4f5de0bb78f5daaaf69890b442701dc42094a59433cef136f6dc85e6fbce989bc8ff7ce8ad1ed1929c8501b13e24f2646
+DIST lightspark-0.8.2.tar.gz 1996482 BLAKE2B 09ef5f4bc4e78efe8c8ddb305e0c47091ba5b27c9b3bb2dd782079bc05a4836d43a80b47d1c30eba424b5d43a724502235a60c08451df4c8526b15a32274dbb4 SHA512 0ff636ad59523726232d9c2105843dc9ea835526c300bca7833e6d1a0ebf7630c1d10109143baabc16f95c1c954094603c945b705a6c9fb02f369e94fead034e
diff --git a/www-plugins/lightspark/lightspark-0.8.2.ebuild b/www-plugins/lightspark/lightspark-0.8.2.ebuild
new file mode 100644
index 00000000000..a844f48a701
--- /dev/null
+++ b/www-plugins/lightspark/lightspark-0.8.2.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit cmake-utils toolchain-funcs xdg-utils
+
+DESCRIPTION="High performance flash player"
+HOMEPAGE="http://lightspark.github.io/"
+SRC_URI="https://github.com/lightspark/lightspark/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cpu_flags_x86_sse2 curl ffmpeg gles libav nsplugin ppapi profile rtmp"
+
+# Note: no LLVM since it's broken upstream
+RDEPEND="app-arch/xz-utils:0=
+ dev-cpp/glibmm:2=
+ >=dev-libs/boost-1.42:0=
+ dev-libs/glib:2=
+ dev-libs/libpcre:3=[cxx]
+ media-fonts/liberation-fonts
+ media-libs/freetype:2=
+ media-libs/libpng:0=
+ media-libs/libsdl2:0=
+ media-libs/sdl2-mixer:0=
+ sys-libs/zlib:0=
+ x11-libs/cairo:0=
+ x11-libs/libX11:0=
+ x11-libs/pango:0=
+ virtual/jpeg:0=
+ curl? ( net-misc/curl:0= )
+ ffmpeg? (
+ libav? ( <media-video/libav-13_pre:0= )
+ !libav? ( media-video/ffmpeg:0= )
+ )
+ gles? ( media-libs/mesa:0=[gles2] )
+ !gles? (
+ >=media-libs/glew-1.5.3:0=
+ virtual/opengl:0=
+ )
+ rtmp? ( media-video/rtmpdump:0= )"
+DEPEND="${RDEPEND}
+ amd64? ( dev-lang/nasm )
+ x86? ( dev-lang/nasm )
+ virtual/pkgconfig"
+
+S=${WORKDIR}/${P/_rc*/}
+
+src_configure() {
+ local mycmakeargs=(
+ -DENABLE_CURL=$(usex curl)
+ -DENABLE_GLES2=$(usex gles)
+ -DENABLE_LIBAVCODEC=$(usex ffmpeg)
+ -DENABLE_RTMP=$(usex rtmp)
+
+ -DENABLE_MEMORY_USAGE_PROFILING=$(usex profile)
+ -DENABLE_PROFILING=$(usex profile)
+ -DENABLE_SSE2=$(usex cpu_flags_x86_sse2)
+
+ -DCOMPILE_NPAPI_PLUGIN=$(usex nsplugin)
+ -DPLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/${PN}/plugins
+ # TODO: install /etc/chromium file? block adobe-flash?
+ -DCOMPILE_PPAPI_PLUGIN=$(usex ppapi)
+ -DPPAPI_PLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/chromium-browser/${PN}
+ )
+
+ cmake-utils_src_configure
+}
+
+src_install() {
+ cmake-utils_src_install
+
+ if use nsplugin; then
+ # copied from nsplugins.eclass, that's broken in EAPI 7
+ dodir /usr/$(get_libdir)/nsbrowser/plugins
+ dosym ../../lightspark/plugins/liblightsparkplugin.so \
+ /usr/$(get_libdir)/nsbrowser/plugins/liblightsparkplugin.so
+ fi
+}
+
+pkg_postinst() {
+ xdg_icon_cache_update
+ xdg_desktop_database_update
+
+ if use nsplugin && has_version "www-plugins/gnash[nsplugin]"; then
+ elog "Having two plugins installed for the same MIME type may confuse"
+ elog "Mozilla based browsers. It is recommended to disable the nsplugin"
+ elog "USE flag for either gnash or lightspark. For details, see"
+ elog "https://bugzilla.mozilla.org/show_bug.cgi?id=581848"
+ fi
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+ xdg_desktop_database_update
+}