summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMikle Kolyada <zlogene@gentoo.org>2020-02-09 19:48:07 +0300
committerMikle Kolyada <zlogene@gentoo.org>2020-02-09 19:48:17 +0300
commit71989131caac4f0f438788ae019ab4806a1fdb7c (patch)
treedf161dcfeb01fbe07fa4d2f4851d9e1fe5eb89f3 /www-servers/lighttpd
parentsci-visualization/pythonprop: Switch to PYTHON_MULTI_USEDEP API (diff)
downloadgentoo-71989131caac4f0f438788ae019ab4806a1fdb7c.tar.gz
gentoo-71989131caac4f0f438788ae019ab4806a1fdb7c.tar.bz2
gentoo-71989131caac4f0f438788ae019ab4806a1fdb7c.zip
www-servers/lighttpd: Drop live ebuild
Package-Manager: Portage-2.3.84, Repoman-2.3.20 Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>
Diffstat (limited to 'www-servers/lighttpd')
-rw-r--r--www-servers/lighttpd/lighttpd-9999.ebuild217
1 files changed, 0 insertions, 217 deletions
diff --git a/www-servers/lighttpd/lighttpd-9999.ebuild b/www-servers/lighttpd/lighttpd-9999.ebuild
deleted file mode 100644
index 4db91887f92..00000000000
--- a/www-servers/lighttpd/lighttpd-9999.ebuild
+++ /dev/null
@@ -1,217 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools eutils readme.gentoo-r1 systemd git-r3
-
-DESCRIPTION="Lightweight high-performance web server"
-HOMEPAGE="https://www.lighttpd.net
- https://github.com/lighttpd"
-EGIT_REPO_URI="https://git.lighttpd.net/lighttpd1.4.git git+ssh://git@lighttpd.net/lighttpd/lighttpd1.4.git git://git.lighttpd.net/lighttpd/lighttpd1.4.git"
-
-LICENSE="BSD GPL-2"
-SLOT="0"
-KEYWORDS=""
-IUSE="bzip2 doc fam gdbm ipv6 kerberos ldap libev libressl lua minimal mmap memcached mysql pcre php rrdtool selinux ssl test webdav xattr zlib"
-RESTRICT="!test? ( test )"
-
-REQUIRED_USE="kerberos? ( ssl !libressl )"
-
-COMMON_DEPEND="
- bzip2? ( app-arch/bzip2 )
- fam? ( virtual/fam )
- gdbm? ( sys-libs/gdbm )
- ldap? ( >=net-nds/openldap-2.1.26 )
- libev? ( >=dev-libs/libev-4.01 )
- lua? ( >=dev-lang/lua-5.1:= )
- memcached? ( dev-libs/libmemcached )
- mysql? ( >=virtual/mysql-4.0 )
- pcre? ( >=dev-libs/libpcre-3.1 )
- php? ( dev-lang/php:*[cgi] )
- rrdtool? ( net-analyzer/rrdtool )
- ssl? (
- !libressl? ( >=dev-libs/openssl-0.9.7:0= )
- libressl? ( dev-libs/libressl:= )
- )
- webdav? (
- dev-libs/libxml2
- >=dev-db/sqlite-3
- sys-fs/e2fsprogs
- )
- xattr? ( kernel_linux? ( sys-apps/attr ) )
- zlib? ( >=sys-libs/zlib-1.1 )
- acct-group/lighttpd
- acct-user/lighttpd"
-
-DEPEND="${COMMON_DEPEND}
- virtual/pkgconfig
- doc? ( dev-python/docutils )
- test? (
- virtual/perl-Test-Harness
- dev-libs/fcgi
- )"
-
-RDEPEND="${COMMON_DEPEND}
- selinux? ( sec-policy/selinux-apache )
-"
-
-# update certain parts of lighttpd.conf based on conditionals
-update_config() {
- local config="${D}/etc/lighttpd/lighttpd.conf"
-
- # enable php/mod_fastcgi settings
- use php && { sed -i -e 's|#.*\(include.*fastcgi.*$\)|\1|' ${config} || die; }
-
- # enable stat() caching
- use fam && { sed -i -e 's|#\(.*stat-cache.*$\)|\1|' ${config} || die; }
-
- # automatically listen on IPv6 if built with USE=ipv6. Bug #234987
- use ipv6 && { sed -i -e 's|# server.use-ipv6|server.use-ipv6|' ${config} || die; }
-}
-
-# remove non-essential stuff (for USE=minimal)
-remove_non_essential() {
- local libdir="${D}/usr/$(get_libdir)/${PN}"
-
- # text docs
- use doc || rm -fr "${D}"/usr/share/doc/${PF}/txt
-
- # non-essential modules
- rm -f \
- ${libdir}/mod_{compress,evhost,expire,proxy,scgi,secdownload,simple_vhost,status,setenv,trigger*,usertrack}.*
-
- # allow users to keep some based on USE flags
- use pcre || rm -f ${libdir}/mod_{ssi,re{direct,write}}.*
- use webdav || rm -f ${libdir}/mod_webdav.*
- use mysql || rm -f ${libdir}/mod_mysql_vhost.*
- use lua || rm -f ${libdir}/mod_{cml,magnet}.*
- use rrdtool || rm -f ${libdir}/mod_rrdtool.*
- use zlib || rm -f ${libdir}/mod_compress.*
-}
-
-pkg_setup() {
- if ! use pcre ; then
- ewarn "It is highly recommended that you build ${PN}"
- ewarn "with perl regular expressions support via USE=pcre."
- ewarn "Otherwise you lose support for some core options such"
- ewarn "as conditionals and modules such as mod_re{write,direct}"
- ewarn "and mod_ssi."
- fi
-
- enewgroup lighttpd
- enewuser lighttpd -1 -1 /var/www/localhost/htdocs lighttpd
-
- DOC_CONTENTS="IPv6 migration guide:\n
- http://redmine.lighttpd.net/projects/lighttpd/wiki/IPv6-Config"
-}
-
-src_prepare() {
- #dev-python/docutils installs rst2html.py not rst2html
- sed -i -e 's|\(rst2html\)|\1.py|g' doc/outdated/Makefile.am || \
- die "sed doc/Makefile.am failed"
- eautoreconf
- default
-}
-
-src_configure() {
- econf --libdir=/usr/$(get_libdir)/${PN} \
- --enable-lfs \
- $(use_enable ipv6) \
- $(use_enable mmap) \
- $(use_with bzip2) \
- $(use_with fam) \
- $(use_with gdbm) \
- $(use_with kerberos kerberos5) \
- $(use_with ldap) \
- $(use_with libev) \
- $(use_with lua) \
- $(use_with memcached memcache) \
- $(use_with mysql) \
- $(use_with pcre) \
- $(use_with ssl openssl) \
- $(use_with webdav webdav-props) \
- $(use_with webdav webdav-locks) \
- $(use_with xattr attr) \
- $(use_with zlib)
-}
-
-src_compile() {
- emake
-
- if use doc ; then
- einfo "Building HTML documentation"
- cd doc || die
- emake html
- fi
-}
-
-src_test() {
- if [[ ${EUID} -eq 0 ]]; then
- default_src_test
- else
- ewarn "test skipped, please re-run as root if you wish to test ${PN}"
- fi
-}
-
-src_install() {
- default
-
- # init script stuff
- newinitd "${FILESDIR}"/lighttpd.initd lighttpd
- newconfd "${FILESDIR}"/lighttpd.confd lighttpd
- use fam && has_version app-admin/fam && \
- { sed -i 's/after famd/need famd/g' "${D}"/etc/init.d/lighttpd || die; }
-
- # configs
- insinto /etc/lighttpd
- doins "${FILESDIR}"/conf/lighttpd.conf
- doins "${FILESDIR}"/conf/mime-types.conf
- doins "${FILESDIR}"/conf/mod_cgi.conf
- doins "${FILESDIR}"/conf/mod_fastcgi.conf
-
- # update lighttpd.conf directives based on conditionals
- update_config
-
- # docs
- dodoc AUTHORS README NEWS doc/scripts/*.sh
- newdoc doc/config//lighttpd.conf lighttpd.conf.distrib
- use ipv6 && readme.gentoo_create_doc
-
- use doc && dodoc -r doc
-
- docinto txt
- dodoc doc/outdated/*.txt
-
- # logrotate
- insinto /etc/logrotate.d
- newins "${FILESDIR}"/lighttpd.logrotate-r1 lighttpd
-
- keepdir /var/l{ib,og}/lighttpd /var/www/localhost/htdocs
- fowners lighttpd:lighttpd /var/l{ib,og}/lighttpd
- fperms 0750 /var/l{ib,og}/lighttpd
-
- #spawn-fcgi may optionally be installed via www-servers/spawn-fcgi
- rm -f "${D}"/usr/bin/spawn-fcgi "${D}"/usr/share/man/man1/spawn-fcgi.*
-
- use minimal && remove_non_essential
-
- systemd_dounit "${FILESDIR}/${PN}.service"
- systemd_dotmpfilesd "${FILESDIR}/${PN}.tmpfiles.conf"
-}
-
-pkg_postinst () {
- use ipv6 && readme.gentoo_print_elog
-
- if [[ -f ${ROOT}etc/conf.d/spawn-fcgi.conf ]] ; then
- einfo "spawn-fcgi is now provided by www-servers/spawn-fcgi."
- einfo "spawn-fcgi's init script configuration is now located"
- einfo "at /etc/conf.d/spawn-fcgi."
- fi
-
- if [[ -f ${ROOT}etc/lighttpd.conf ]] ; then
- elog "Gentoo has a customized configuration,"
- elog "which is now located in /etc/lighttpd. Please migrate your"
- elog "existing configuration."
- fi
-}