summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAlfredo Tupone <tupone@gentoo.org>2021-04-18 10:32:55 +0200
committerAlfredo Tupone <tupone@gentoo.org>2021-04-18 10:32:55 +0200
commit5f62aad9242d7a8b39e271b89aaa2b1a3fe0077d (patch)
tree09092a084ef7f1231ec677fc4f41e493d32e46a0 /www-servers/moonbridge/moonbridge-1.0.1.ebuild
parentdev-java/xerces: min java 11 (diff)
downloadgentoo-5f62aad9242d7a8b39e271b89aaa2b1a3fe0077d.tar.gz
gentoo-5f62aad9242d7a8b39e271b89aaa2b1a3fe0077d.tar.bz2
gentoo-5f62aad9242d7a8b39e271b89aaa2b1a3fe0077d.zip
www-servers/moonbridge: web server for lua application
Package-Manager: Portage-3.0.13, Repoman-3.0.2 Signed-off-by: Alfredo Tupone <tupone@gentoo.org>
Diffstat (limited to 'www-servers/moonbridge/moonbridge-1.0.1.ebuild')
-rw-r--r--www-servers/moonbridge/moonbridge-1.0.1.ebuild49
1 files changed, 49 insertions, 0 deletions
diff --git a/www-servers/moonbridge/moonbridge-1.0.1.ebuild b/www-servers/moonbridge/moonbridge-1.0.1.ebuild
new file mode 100644
index 00000000000..206544b88f6
--- /dev/null
+++ b/www-servers/moonbridge/moonbridge-1.0.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{2,3} )
+
+inherit lua-single
+
+MYP=${PN}-v${PV}
+
+DESCRIPTION="Network Server for Lua Applications"
+HOMEPAGE="https://www.public-software-group.org/moonbridge"
+SRC_URI="https://www.public-software-group.org/pub/projects/${PN}/v${PV}/${MYP}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+DEPEND="
+ ${LUA_DEPS}
+ dev-libs/libbsd"
+RDEPEND="${DEPEND}"
+BDEPEND="sys-devel/pmake
+ virtual/pkgconfig"
+
+S="${WORKDIR}"/${MYP}
+
+PATCHES=( "${FILESDIR}"/${P}-gentoo.patch )
+
+DOCS=( README reference.txt )
+
+src_compile() {
+ pmake CC=$(tc-getCC) LUA_INCLUDE="$(lua_get_include_dir)" \
+ MOONBR_LUA_PATH=/usr/lib/moonbridge/?.lua \
+ LUA_LIBRARY="$(lua_get_LIBS)" LUA_LIBDIR=/usr/$(get_libdir)
+}
+
+src_install() {
+ einstalldocs
+ docinto examples
+ dodoc example_*
+ dodoc helloworld.lua
+ dobin ${PN}
+ insinto /usr/lib/${PN}
+ doins moonbridge_http.lua
+ docompress -x /usr/share/doc/${PF}/examples
+}