summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorRalph Seichter <github@seichter.de>2019-10-24 20:34:17 +0200
committerJoonas Niilola <juippis@gentoo.org>2019-10-28 08:39:36 +0200
commit424ed4537c26ea62a23bb040e691477ac1bc0e1b (patch)
treef4c5a4eaf24fb02bf0402461d474210fb28a4c64 /www-servers/nginx-unit
parentapp-text/pdfminer: version bump to 20191020, Python 3 only (diff)
downloadgentoo-424ed4537c26ea62a23bb040e691477ac1bc0e1b.tar.gz
gentoo-424ed4537c26ea62a23bb040e691477ac1bc0e1b.tar.bz2
gentoo-424ed4537c26ea62a23bb040e691477ac1bc0e1b.zip
www-servers/nginx-unit: Build related bug fixes
This ebuild addresses CFLAGS/LDFLAGS issues and introduces a USE flag for OpenSSL support. Closes: https://bugs.gentoo.org/696964 Closes: https://bugs.gentoo.org/696966 Closes: https://bugs.gentoo.org/696972 Package-Manager: Portage-2.3.76, Repoman-2.3.16 Signed-off-by: Ralph Seichter <gentoo@seichter.de> Closes: https://github.com/gentoo/gentoo/pull/13417 Signed-off-by: Joonas Niilola <juippis@gentoo.org>
Diffstat (limited to 'www-servers/nginx-unit')
-rw-r--r--www-servers/nginx-unit/nginx-unit-1.12.0-r1.ebuild72
1 files changed, 72 insertions, 0 deletions
diff --git a/www-servers/nginx-unit/nginx-unit-1.12.0-r1.ebuild b/www-servers/nginx-unit/nginx-unit-1.12.0-r1.ebuild
new file mode 100644
index 00000000000..9554af89ad6
--- /dev/null
+++ b/www-servers/nginx-unit/nginx-unit-1.12.0-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=(python2_7 python3_{5,6,7})
+
+inherit python-single-r1
+
+MY_P="unit-${PV}"
+DESCRIPTION="Dynamic web and application server"
+HOMEPAGE="https://unit.nginx.org"
+SRC_URI="https://unit.nginx.org/download/${MY_P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+MY_USE="perl python ruby"
+MY_USE_PHP="php5-6 php7-1 php7-2 php7-3"
+IUSE="${MY_USE} ${MY_USE_PHP} ssl"
+REQUIRED_USE="|| ( ${IUSE} )
+ python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="perl? ( dev-lang/perl:= )
+ php5-6? ( dev-lang/php:5.6[embed] )
+ php7-1? ( dev-lang/php:7.1[embed] )
+ php7-2? ( dev-lang/php:7.2[embed] )
+ php7-3? ( dev-lang/php:7.3[embed] )
+ python? ( ${PYTHON_DEPS} )
+ ruby? ( dev-lang/ruby:= )
+ ssl? ( dev-libs/openssl:= )"
+RDEPEND="${DEPEND}"
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+ local opt=(
+ --control=unix:/run/${PN}.sock
+ --log=/var/log/${PN}
+ --modules=$(get_libdir)/${PN}
+ --pid=/run/${PN}.pid
+ --prefix=/usr
+ --state=/var/lib/${PN}
+ )
+ use ssl && opt+=( --openssl )
+
+ ./configure ${opt[@]} --cc-opt="${CFLAGS}" --ld-opt="${LDFLAGS}" || die "Core configuration failed"
+ for flag in ${MY_USE} ; do
+ if use ${flag} ; then
+ ./configure ${flag} || die "Module configuration failed: ${flag}"
+ fi
+ done
+ for flag in ${MY_USE_PHP} ; do
+ if use ${flag} ; then
+ local php_slot="/usr/$(get_libdir)/${flag/-/.}"
+ ./configure php \
+ --module=${flag} \
+ --config=${php_slot}/bin/php-config \
+ --lib-path=${php_slot}/$(get_libdir) || die "Module configuration failed: ${flag}"
+ fi
+ done
+}
+
+src_install() {
+ default
+ diropts -m 0770
+ keepdir /var/lib/${PN}
+ newinitd "${FILESDIR}/${PN}.initd" ${PN}
+}