x11-libs/libva-intel-driver: bump to 2.1.0

Package-Manager: Portage-2.3.24, Repoman-2.3.6

1 files changed, 56 insertions, 0 deletions

diff --git a/x11-libs/libva-intel-driver/libva-intel-driver-2.1.0.ebuild b/x11-libs/libva-intel-driver/libva-intel-driver-2.1.0.ebuild
new file mode 100644
index 00000000000..a440f522871
--- /dev/null
+++ b/x11-libs/libva-intel-driver/libva-intel-driver-2.1.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+SCM=""
+if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
+	SCM=git-r3
+	EGIT_BRANCH=master
+	EGIT_REPO_URI="https://github.com/intel/intel-vaapi-driver"
+fi
+
+AUTOTOOLS_AUTORECONF="yes"
+inherit autotools-multilib ${SCM}
+
+DESCRIPTION="HW video decode support for Intel integrated graphics"
+HOMEPAGE="https://github.com/intel/intel-vaapi-driver"
+if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/intel/intel-vaapi-driver/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/intel-vaapi-driver-${PV}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+if [ "${PV%9999}" = "${PV}" ] ; then
+	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+else
+	KEYWORDS=""
+fi
+IUSE="+drm wayland X"
+
+RDEPEND=">=x11-libs/libva-2.0.0:=[X?,wayland?,drm?,${MULTILIB_USEDEP}]
+	>=x11-libs/libdrm-2.4.52[video_cards_intel,${MULTILIB_USEDEP}]
+	wayland? ( >=media-libs/mesa-9.1.6[egl,${MULTILIB_USEDEP}] >=dev-libs/wayland-1.11[${MULTILIB_USEDEP}] )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS NEWS README )
+AUTOTOOLS_PRUNE_LIBTOOL_FILES="all"
+
+src_prepare() {
+	sed -e 's/intel-gen4asm/\0diSaBlEd/g' -i configure.ac || die
+	autotools-multilib_src_prepare
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable drm)
+		$(use_enable wayland)
+		$(use_enable X x11)
+	)
+	autotools-utils_src_configure
+}