summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJeroen Roovers <jer@gentoo.org>2020-07-09 12:12:54 +0200
committerJeroen Roovers <jer@gentoo.org>2020-07-09 12:14:28 +0200
commit377404e63724561b7fe5b7b559a16893d8468bec (patch)
tree6c2002d172a48bc26d26f9a7db5c784a529397fb /x11-misc/fbpanel/fbpanel-7.0-r2.ebuild
parentdev-python/denonavr: remove old (diff)
downloadgentoo-377404e63724561b7fe5b7b559a16893d8468bec.tar.gz
gentoo-377404e63724561b7fe5b7b559a16893d8468bec.tar.bz2
gentoo-377404e63724561b7fe5b7b559a16893d8468bec.zip
x11-misc/fbpanel: Add python3 support, drop python2 support
- Convert build system to python3 thanks to Alexey Mishustin - Set BDEPEND Package-Manager: Portage-2.3.103, Repoman-2.3.23 Closes: https://bugs.gentoo.org/731308 Signed-off-by: Jeroen Roovers <jer@gentoo.org>
Diffstat (limited to 'x11-misc/fbpanel/fbpanel-7.0-r2.ebuild')
-rw-r--r--x11-misc/fbpanel/fbpanel-7.0-r2.ebuild65
1 files changed, 65 insertions, 0 deletions
diff --git a/x11-misc/fbpanel/fbpanel-7.0-r2.ebuild b/x11-misc/fbpanel/fbpanel-7.0-r2.ebuild
new file mode 100644
index 00000000000..b122768dea1
--- /dev/null
+++ b/x11-misc/fbpanel/fbpanel-7.0-r2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit python-any-r1 toolchain-funcs
+
+DESCRIPTION="light-weight X11 desktop panel"
+HOMEPAGE="https://aanatoly.github.io/fbpanel/"
+SRC_URI="https://aanatoly.github.io/fbpanel/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~mips ~ppc ~ppc64 ~x86"
+IUSE="alsa"
+
+RDEPEND="
+ dev-libs/glib:2
+ x11-libs/gdk-pixbuf:2[X]
+ x11-libs/gtk+:2
+ x11-libs/libX11
+ alsa? ( media-libs/alsa-lib )
+"
+DEPEND="
+ ${RDEPEND}
+ x11-base/xorg-proto
+"
+BDEPEND="
+ ${PYTHON_DEPS}
+ virtual/pkgconfig
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-6.1-underlinking.patch
+ "${FILESDIR}"/${PN}-7.0-clang.patch
+ "${FILESDIR}"/${PN}-7.0-fno-common.patch
+ "${FILESDIR}"/${PN}-7.0-images.patch
+ "${FILESDIR}"/${PN}-7.0-python3-shebangs.patch
+)
+
+src_prepare() {
+ default
+ 2to3 -n -w --no-diffs configure .config/*.py || die
+}
+
+src_configure() {
+ tc-export CC
+ # not autotools based
+ local myconfigure=(
+ ./configure V=1
+ --mandir="${EPREFIX}"/usr/share/man/man1
+ --datadir="${EPREFIX}"/usr/share/${PN}
+ --prefix="${EPREFIX}"/usr
+ --libdir="${EPREFIX}"/usr/$(get_libdir)/${PN}
+ $(usex alsa --sound --no-sound)
+ )
+ echo ${myconfigure[@]} || die
+ ${myconfigure[@]} || die
+}
+
+pkg_postinst() {
+ elog "For the volume plugin to work, you need to configure your kernel"
+ elog "with CONFIG_SND_MIXER_OSS or CONFIG_SOUND_PRIME or some other means"
+ elog "that provide the /dev/mixer device node."
+}