summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichael Palimaka <kensington@gentoo.org>2018-02-11 13:33:21 +1100
committerMichael Palimaka <kensington@gentoo.org>2018-02-11 13:37:43 +1100
commit69067acbe601049b4bf27e80342fc68c1ff6da6a (patch)
treeba4377cc8425aba853c049fd946cc563d992e01c /x11-misc/qtfm
parentapp-shells/bash: Bump to version 4.4_p19 (diff)
downloadgentoo-69067acbe601049b4bf27e80342fc68c1ff6da6a.tar.gz
gentoo-69067acbe601049b4bf27e80342fc68c1ff6da6a.tar.bz2
gentoo-69067acbe601049b4bf27e80342fc68c1ff6da6a.zip
x11-misc/qtfm: revision bump address assorted issues
* Replace incorrect dev-qt/qtchooser dependency with dev-qt/linguist-tools:5 and direct binary call * Remove L10N USE flags that serve no purpose * Avoid installing duplicate documentation files * Avoid unnecessary mimeinfo database update * Correct LICENSE * Add missing unpack dependency Package-Manager: Portage-2.3.19, Repoman-2.3.6
Diffstat (limited to 'x11-misc/qtfm')
-rw-r--r--x11-misc/qtfm/qtfm-5.9-r1.ebuild61
1 files changed, 61 insertions, 0 deletions
diff --git a/x11-misc/qtfm/qtfm-5.9-r1.ebuild b/x11-misc/qtfm/qtfm-5.9-r1.ebuild
new file mode 100644
index 00000000000..4a2ca8ca87b
--- /dev/null
+++ b/x11-misc/qtfm/qtfm-5.9-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit qmake-utils xdg-utils
+
+DESCRIPTION="A small, lightweight file manager for desktops based on pure Qt"
+HOMEPAGE="http://www.qtfm.org/"
+SRC_URI="https://dev.gentoo.org/~jer/${P}.zip"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtwidgets:5
+ sys-apps/file
+"
+DEPEND="${RDEPEND}
+ app-arch/unzip
+ dev-qt/linguist-tools:5
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-5.5-gcc6.patch )
+
+S=${WORKDIR}/${PN}-master
+
+src_prepare() {
+ rm translations/${PN}_XX.ts || die
+
+ default
+
+ sed -i \
+ -e '/MimeType=/s|$|;|' \
+ -e '/Categories=/s|$|;System;FileTools;|' \
+ ${PN}.desktop || die
+
+ sed -i -e '/^INSTALLS/s/docs//' ${PN}.pro || die
+}
+
+src_configure() {
+ "$(qt5_get_bindir)"/lrelease translations/*.ts || die
+ eqmake5
+}
+
+src_install() {
+ emake INSTALL_ROOT="${D}" install
+ einstalldocs
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+}