summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
-rw-r--r--app-text/coolreader/Manifest1
-rw-r--r--app-text/coolreader/coolreader-3.2.58.ebuild67
2 files changed, 68 insertions, 0 deletions
diff --git a/app-text/coolreader/Manifest b/app-text/coolreader/Manifest
index 829b30a9272..50aedc9a87a 100644
--- a/app-text/coolreader/Manifest
+++ b/app-text/coolreader/Manifest
@@ -1 +1,2 @@
DIST coolreader-3.2.57.tar.gz 13281238 BLAKE2B 8a6739f38d72b13af7b79160dee8cfc08bd9e54d3698fd44c7f6ad8bd575b1f389c2c349c1e2ef71a55fb0068e9d64b5baa4a0a8b945cdb873e833178d81cbbe SHA512 d5bf46f7dbf19177a54742d5c300002c8b7a504052bd003d2e1a7380ac3460dbe648d7f923d26e6390e9296ce6b090c947204725ab2a30c78f26893868a61161
+DIST coolreader-3.2.58.tar.gz 13454079 BLAKE2B e3b85ffbb3e4023a8c0567879a4a67d21141c1025b58f7d2c5017cab773e989e797229529440167a8c83db810f599566a77aaaab06b34081472f0e4b20293ec9 SHA512 d1d3e60bf5b73c20617937850912d7c452863bd5c91f0154be320ad256f774f368039896ad5e8acfc3cafa7361e8c11ca526accf0a14dabb79f059255989bac6
diff --git a/app-text/coolreader/coolreader-3.2.58.ebuild b/app-text/coolreader/coolreader-3.2.58.ebuild
new file mode 100644
index 00000000000..32e43b6cdee
--- /dev/null
+++ b/app-text/coolreader/coolreader-3.2.58.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+WX_GTK_VER="3.0-gtk3"
+PLOCALES="bg cs de es hu pl ru uk"
+inherit cmake plocale wxwidgets xdg
+
+CR_PV=$(ver_rs 3 '-')
+SRC_URI="https://github.com/buggins/${PN}/archive/cr${CR_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-cr${CR_PV}"
+
+DESCRIPTION="CoolReader - reader of eBook files (fb2,epub,htm,rtf,txt)"
+HOMEPAGE="https://github.com/buggins/coolreader/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="wxwidgets"
+
+CDEPEND="sys-libs/zlib
+ media-libs/libpng:0
+ virtual/jpeg:0
+ media-libs/freetype
+ dev-libs/fribidi
+ media-libs/fontconfig
+ media-libs/harfbuzz
+ dev-libs/libunibreak
+ wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER} )
+ !wxwidgets? ( dev-qt/qtcore:5 dev-qt/qtgui:5 dev-qt/qtwidgets:5 )"
+BDEPEND="${CDEPEND}
+ !wxwidgets? ( dev-qt/linguist-tools:5 )"
+RDEPEND="${CDEPEND}
+ wxwidgets? ( || ( media-fonts/liberation-fonts media-fonts/corefonts ) )"
+
+src_prepare() {
+ cmake_src_prepare
+ xdg_src_prepare
+
+ # locales
+ plocale_find_changes "${S}"/cr3qt/src/i18n 'cr3_' '.ts'
+ sed -e "s|SET(LANGUAGES .*)|SET(LANGUAGES $(plocale_get_locales))|" \
+ -i "${S}"/cr3qt/CMakeLists.txt \
+ || die "sed CMakeLists.txt failed"
+}
+
+src_configure() {
+ CMAKE_USE_DIR="${S}"
+ CMAKE_BUILD_TYPE="Release"
+ if use wxwidgets; then
+ setup-wxwidgets
+ local mycmakeargs=(-D GUI=WX)
+ else
+ local mycmakeargs=(-D GUI=QT5)
+ fi
+ cmake_src_configure
+}
+
+src_install() {
+ cmake_src_install
+ if ! use wxwidgets; then
+ mv "${D}"/usr/share/doc/cr3/changelog.gz "${D}"/usr/share/doc/${PF}/ || die "mv changelog.gz failed"
+ rmdir "${D}"/usr/share/doc/cr3 || die "rmdir doc/cr3 failed"
+ gunzip "${D}"/usr/share/doc/${PF}/changelog.gz || die "gunzip changelog.gz failed"
+ gunzip "${D}"/usr/share/man/man1/cr3.1.gz || die "gunzip cr3.1.gz failed"
+ fi
+}