summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
-rw-r--r--dev-python/pytest/Manifest1
-rw-r--r--dev-python/pytest/pytest-4.6.11.ebuild84
2 files changed, 85 insertions, 0 deletions
diff --git a/dev-python/pytest/Manifest b/dev-python/pytest/Manifest
index 6b2f9ee3087..39399022a8b 100644
--- a/dev-python/pytest/Manifest
+++ b/dev-python/pytest/Manifest
@@ -1,6 +1,7 @@
DIST pytest-3.10.1.tar.gz 892420 BLAKE2B 38849ae69bf4380bc1a99aa105cac04be078da4460373dfc16fa555238b2830fa2f5ae6c19de8aa2af9ac18d87c5d2705d62f7b2e67e4a62d843f6a28bbd76fd SHA512 30ff79c0fdcbeef68e1191ff400a20428e391717f06957f554b694b94baaaa565dca01346fe989c3e443c4402f3b2bdbd5564f6303a4447f933fb54cba45628f
DIST pytest-4.5.0.tar.gz 943607 BLAKE2B 49a0e91fda7f4231fdd39f90eb2daa344d3034c10faff221330ea0ae7482a2a7d0fb9443a0a264db00f1d92568d5a6005cb73e07d8643b46906f7ecff831adcb SHA512 cbffc6216f83491b1de241058315c116697bfaa5206b5f558192a7f861d43dd036d30d0d689bedae7bdee4f0258dd19ef5827c356e11863dd596a5fabe8249fc
DIST pytest-4.6.10.tar.gz 951516 BLAKE2B f87d00c3d69990f39369ec6af8c4b88d8b7da9bbdc9fcb324243ea2164a501e1b23d1c2a7f92049b58786fc2f1006673a5b5348e2367a8ca476650623c1f67ed SHA512 73668967f6568654cdf92e260ada79d9685fcfc30967499709caeb12527e39a9e886f057c4c73e8a39125c0fbfcd674d905b7023402ce0ab9e836aa77d3888cb
+DIST pytest-4.6.11.tar.gz 952305 BLAKE2B af07adf5e8fc614b1fdb7b5673fb9c557ff0dd3f22e2f3bf853c643c5c8bd38f307018579299b700d90034a826db73a3e569857d6d6f7ac6646ace894b35a39b SHA512 6fddf4944bd9fab83024aa2d338d54aaf3d164bd5c7f634357376f3b0d2dab6a43d784e7fb567236c2d2f029151c5d9e2cb36c22e9b551c2c8823c52a2246e9c
DIST pytest-4.6.9.tar.gz 956816 BLAKE2B 7eaeaa0d47c17836a35d9cdc97663f8ef65253099b21d60a7ffc3655d8bd93c6b4e33045caa6c8ab9bb8b920b93e596ba86d8eac4ab07b3b7a5989b38312f4fc SHA512 ab45a8662aa798a6ae224ad2cd68e043c605e4830c76cb6c6aca3cfccef232c024cbbb6c48c9bae19148099c339abfef3270a2208cc7e5c37a10b34b0aa6ba79
DIST pytest-5.4.1.tar.gz 1017924 BLAKE2B 2892b06655384c8453963e8444e7c1659f4ce60410afe6d01c480da4858628f6c8fd8774131c5bfaca3b3baf9936e3e4d607788b390d37f7aee90cb39c4ba15c SHA512 50d94158817561316cfb4c6ad4481858a76cfe44ba964cc7a3bb81d3701eb621ca5cd46c4be24644134417d8bf7e7771f4b3a30af71fde5ea9705c3241fa2878
DIST pytest-5.4.2.tar.gz 1020640 BLAKE2B e10ce7a2dbc1ff42ffbe02c3a9f72b4c829c5cc80ba9a50ae015d181c03916a807ee2b13d40e0d7590844f67f8b68e926c770d298fd839c3cf24d9daa4b4e1e7 SHA512 c92ffa613a02cee2580d690c24b76f16957082b138cf7c51d277b0fb5098fab2272ab73295e5e368cbd908026130a9185a35f8792054e36b7ade0a05f7f3f192
diff --git a/dev-python/pytest/pytest-4.6.11.ebuild b/dev-python/pytest/pytest-4.6.11.ebuild
new file mode 100644
index 00000000000..f7a45485dc9
--- /dev/null
+++ b/dev-python/pytest/pytest-4.6.11.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python2_7 python3_{6,7,8,9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Simple powerful testing with Python"
+HOMEPAGE="http://pytest.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# When bumping, please check setup.py for the proper py version
+PY_VER="1.5.0"
+
+# pathlib2 has been added to stdlib before py3.6, but pytest needs __fspath__
+# support, which only came in py3.6.
+RDEPEND="
+ >=dev-python/atomicwrites-1.0[${PYTHON_USEDEP}]
+ >=dev-python/attrs-17.4.0[${PYTHON_USEDEP}]
+ >=dev-python/more-itertools-4.0.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/importlib_metadata[${PYTHON_USEDEP}]
+ ' -2 python3_{5,6,7} pypy3)
+ $(python_gen_cond_dep '
+ dev-python/pathlib2[${PYTHON_USEDEP}]
+ dev-python/funcsigs[${PYTHON_USEDEP}]
+ ' -2)
+ >=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
+ <dev-python/pluggy-1
+ >=dev-python/py-${PY_VER}[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]
+ dev-python/wcwidth[${PYTHON_USEDEP}]"
+
+# flake cause a number of tests to fail
+DEPEND="
+ test? (
+ ${RDEPEND}
+ dev-python/argcomplete[${PYTHON_USEDEP}]
+ >=dev-python/hypothesis-3.56[${PYTHON_USEDEP}]
+ dev-python/nose[${PYTHON_USEDEP}]
+ dev-python/pexpect[${PYTHON_USEDEP}]
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ !!dev-python/flaky
+ !!dev-python/pytest-aiohttp
+ !!dev-python/pytest-asyncio
+ !!dev-python/pytest-django
+ $(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' -2)
+ )"
+
+PATCHES=(
+ "${FILESDIR}/pytest-4.5.0-strip-setuptools_scm.patch"
+ "${FILESDIR}/pytest-4.6.10-timeout.patch"
+)
+
+python_prepare_all() {
+ grep -qF "py>=${PY_VER}" setup.py || die "Incorrect dev-python/py dependency"
+
+ # Something in the ebuild environment causes this to hang/error.
+ # https://bugs.gentoo.org/598442
+ rm testing/test_pdb.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ distutils_install_for_testing
+
+ # In v4.1.1, pytest started being picky about its own verbosity options.
+ # running pytest on itself with -vv made 3 tests fail. This is why we don't
+ # have it below.
+ "${EPYTHON}" "${BUILD_DIR}"/lib/pytest.py --lsof -rfsxX \
+ || die "tests failed with ${EPYTHON}"
+}