summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
-rw-r--r--games-emulation/fceux/fceux-2.2.3-r100.ebuild69
-rw-r--r--profiles/package.mask1
2 files changed, 70 insertions, 0 deletions
diff --git a/games-emulation/fceux/fceux-2.2.3-r100.ebuild b/games-emulation/fceux/fceux-2.2.3-r100.ebuild
new file mode 100644
index 00000000000..734feb3edc8
--- /dev/null
+++ b/games-emulation/fceux/fceux-2.2.3-r100.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-1 )
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit python-any-r1 desktop lua-single scons-utils toolchain-funcs
+
+DESCRIPTION="A portable Famicom/NES emulator, an evolution of the original FCE Ultra"
+HOMEPAGE="https://fceux.com/"
+SRC_URI="mirror://sourceforge/fceultra/${P}.src.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gtk logo +lua +opengl"
+
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
+
+RDEPEND="
+ lua? ( ${LUA_DEPS} )
+ media-libs/libsdl[opengl?,video]
+ logo? ( media-libs/gd[png] )
+ opengl? ( virtual/opengl )
+ gtk? ( x11-libs/gtk+:3 )
+ sys-libs/zlib[minizip]
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-2.2.2-warnings.patch
+ "${FILESDIR}/${P}-python3.patch"
+)
+
+pkg_setup() {
+ python-any-r1_pkg_setup
+ use lua && lua-single_pkg_setup
+}
+
+src_prepare() {
+ default
+
+ tc-export CC CXX
+}
+
+src_compile() {
+ escons \
+ GTK=0 \
+ CREATE_AVI=1 \
+ SYSTEM_LUA=1 \
+ SYSTEM_MINIZIP=1 \
+ GTK3=$(usex gtk 1 0) \
+ LOGO=$(usex logo 1 0) \
+ OPENGL=$(usex opengl 1 0) \
+ LUA=$(usex lua 1 0)
+}
+
+src_install() {
+ dobin bin/fceux
+
+ doman documentation/fceux.6
+ docompress -x /usr/share/doc/${PF}/documentation /usr/share/doc/${PF}/fceux.chm
+ dodoc -r Authors changelog.txt TODO-SDL bin/fceux.chm documentation
+ rm -f "${D}/usr/share/doc/${PF}/documentation/fceux.6"
+ make_desktop_entry fceux FCEUX
+ doicon fceux.png
+}
diff --git a/profiles/package.mask b/profiles/package.mask
index 416fbe81fa8..5a5a92b31b1 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -552,6 +552,7 @@ dev-lua/luacrypto
>=dev-util/geany-plugins-1.37-r100
=games-action/minetest-5.3.0-r100
>=games-arcade/jvgs-0.5-r100
+>=games-emulation/fceux-2.2.3-r100
>=games-engines/love-0.7.2-r100:0.7
>=games-engines/love-0.8.0-r100:0.8
>=games-engines/love-11.3-r100:0