1 files changed, 66 insertions, 0 deletions
diff --git a/app-admin/filebeat/filebeat-6.3.2.ebuild b/app-admin/filebeat/filebeat-6.3.2.ebuild
new file mode 100644
index 000000000000..1c9264bf6ec4
--- /dev/null
+++ b/app-admin/filebeat/filebeat-6.3.2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Lightweight log shipper for Logstash and Elasticsearch"
+HOMEPAGE="https://www.elastic.co/products/beats"
+SRC_URI="https://github.com/elastic/beats/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~x86"
+RESTRICT="test"
+
+DEPEND=">=dev-lang/go-1.10.3"
+RDEPEND="!app-admin/filebeat-bin"
+
+# Do not complain about CFLAGS etc since go projects do not use them.
+QA_FLAGS_IGNORED='.*'
+
+S="${WORKDIR}/src/github.com/elastic/beats"
+
+src_unpack() {
+	mkdir -p "${S%/*}" || die
+	default
+	mv beats-${PV} "${S}" || die
+}
+
+src_prepare() {
+	default
+
+	# avoid Elastic license
+	rm -r x-pack || die
+
+	# use ${PV} instead of git commit id
+	sed -i "s/\(COMMIT_ID=\).*/\1${PV}/g" "${S}/libbeat/scripts/Makefile" || die
+}
+
+src_compile() {
+	GOPATH="${WORKDIR}" emake -C "${S}/filebeat"
+}
+
+src_install() {
+	keepdir /var/{lib,log}/${PN}
+
+	fperms 0750 /var/{lib,log}/${PN}
+
+	newconfd "${FILESDIR}/${PN}.confd" ${PN}
+	newinitd "${FILESDIR}/${PN}.initd.1" ${PN}
+
+	docinto examples
+	dodoc ${PN}/{filebeat.yml,filebeat.reference.yml}
+
+	dobin filebeat/filebeat
+}
+
+pkg_postinst() {
+	if [[ -n "${REPLACING_VERSIONS}" ]]; then
+		elog "Please read the migration guide at:"
+		elog "https://www.elastic.co/guide/en/beats/libbeat/$(ver_cut 1-2)/upgrading.html"
+		elog ""
+	fi
+
+	elog "Example configurations:"
+	elog "${EROOT}/usr/share/doc/${PF}/examples"
+}