summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'app-admin/sysstat/sysstat-12.1.2.ebuild')
-rw-r--r--app-admin/sysstat/sysstat-12.1.2.ebuild85
1 files changed, 85 insertions, 0 deletions
diff --git a/app-admin/sysstat/sysstat-12.1.2.ebuild b/app-admin/sysstat/sysstat-12.1.2.ebuild
new file mode 100644
index 000000000000..d5b74497593a
--- /dev/null
+++ b/app-admin/sysstat/sysstat-12.1.2.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit flag-o-matic multilib systemd toolchain-funcs
+
+DESCRIPTION="System performance tools for Linux"
+HOMEPAGE="http://pagesperso-orange.fr/sebastien.godard/"
+SRC_URI="${HOMEPAGE}${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="debug nls lm_sensors selinux static"
+
+CDEPEND="
+ nls? ( virtual/libintl )
+ lm_sensors? ( sys-apps/lm_sensors:= )
+"
+DEPEND="
+ ${CDEPEND}
+ nls? ( sys-devel/gettext )
+"
+RDEPEND="
+ ${CDEPEND}
+ selinux? ( sec-policy/selinux-sysstat )
+"
+PATCHES=(
+ "${FILESDIR}"/${PN}-11.0.4-cron.patch
+ "${FILESDIR}"/${PN}-11.7.3-flags.patch
+)
+
+SYSSTAT_FAKE_RC_DIR=Gentoo-does-not-use-rc.d
+
+src_prepare() {
+ if use nls; then
+ strip-linguas -i nls/
+ local lingua pofile
+ for pofile in nls/*.po; do
+ lingua=${pofile/nls\/}
+ lingua=${lingua/.po}
+ if ! has ${lingua} ${LINGUAS}; then
+ rm "nls/${lingua}.po" || die
+ fi
+ done
+ fi
+
+ default
+}
+
+src_configure() {
+ tc-export AR
+ use static && append-ldflags -static
+
+ sa_lib_dir=/usr/$(get_libdir)/sa \
+ conf_dir=/etc \
+ rcdir=${SYSSTAT_FAKE_RC_DIR} \
+ econf \
+ $(use_enable debug debuginfo) \
+ $(use_enable lm_sensors sensors) \
+ $(use_enable nls) \
+ --enable-copy-only \
+ --enable-documentation \
+ --enable-install-cron \
+ --with-systemdsystemunitdir=$(systemd_get_systemunitdir)
+}
+
+src_install() {
+ keepdir /var/log/sa
+
+ emake \
+ CHOWN=true \
+ DESTDIR="${D}" \
+ DOC_DIR=/usr/share/doc/${PF} \
+ MANGRPARG='' \
+ install
+
+ dodoc -r contrib/
+
+ rm -r "${D}/${SYSSTAT_FAKE_RC_DIR}" || die
+ newinitd "${FILESDIR}"/${PN}.init.d ${PN}
+ systemd_dounit ${PN}.service
+
+ rm -f "${D}"usr/share/doc/${PF}/COPYING
+}