1 files changed, 57 insertions, 0 deletions
diff --git a/app-admin/yadm/yadm-2.4.0.ebuild b/app-admin/yadm/yadm-2.4.0.ebuild
new file mode 100644
index 000000000000..b6f903a85808
--- /dev/null
+++ b/app-admin/yadm/yadm-2.4.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1
+
+DESCRIPTION="A dotfile manager for the config files in your home folder"
+HOMEPAGE="https://github.com/TheLocehiliosan/yadm/"
+SRC_URI="https://github.com/TheLocehiliosan/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-crypt/gnupg
+	dev-vcs/git
+"
+
+DEPEND="
+	test? ( dev-tcltk/expect dev-python/pytest ${RDEPEND} )
+"
+
+src_compile() {
+	emake "${PN}.md"
+}
+
+src_test() {
+	# test_encryption: needs write access to /tmp
+	# test_alt, test_compat_jinja, test_unit_template_j2: needs envtpl
+	# test_syntax: needs yamllint (not packaged)
+	# test_compat_alt: known broken, tests deprecated features
+	# test_compat_jinja: needs envtpl
+	rm test/test_encryption.py || die
+	rm test/test_alt.py || die
+	rm test/test_compat_jinja.py || die
+	rm test/test_unit_template_j2.py || die
+	rm test/test_syntax.py || die
+	rm test/test_compat_alt.py || die
+
+	pytest || die "Testsuite failed under ${EPYTHON}"
+}
+
+src_install() {
+	einstalldocs
+
+	dobin "${PN}"
+	doman "${PN}.1"
+
+	newbashcomp completion/yadm.bash_completion yadm
+
+	insinto /usr/share/zsh/site-functions
+	newins completion/yadm.zsh_completion _${PN}
+}