1 files changed, 50 insertions, 0 deletions
diff --git a/app-crypt/dehydrated/dehydrated-0.7.0.ebuild b/app-crypt/dehydrated/dehydrated-0.7.0.ebuild
new file mode 100644
index 000000000000..a0b9dd29497c
--- /dev/null
+++ b/app-crypt/dehydrated/dehydrated-0.7.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+DESCRIPTION="a client for signing certificates with an ACME-server"
+HOMEPAGE="https://github.com/lukas2511/dehydrated"
+SRC_URI="https://github.com/lukas2511/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="+cron"
+
+RDEPEND="acct-group/dehydrated
+	acct-user/dehydrated
+	app-shells/bash
+	net-misc/curl
+	cron? ( virtual/cron )"
+
+PATCHES=( "${FILESDIR}"/${P}-fix-CN-extraction-for-older-openssl-versions.patch )
+
+src_configure() {
+	default
+	sed -i  's,^#CONFIG_D=.*,CONFIG_D="/etc/dehydrated/config.d",' docs/examples/config || die "could not set config (CONFIG_D)"
+}
+
+src_install() {
+	dobin ${PN}
+	insinto /etc/${PN}
+	doins docs/examples/{config,domains.txt,hook.sh}
+	fperms u+x /etc/${PN}/hook.sh
+	dodoc docs/*.md
+
+	insinto /etc/${PN}/config.d
+	doins "${FILESDIR}"/00_gentoo.sh
+
+	if use cron ; then
+		insinto /etc/cron.d
+		newins "${FILESDIR}"/cron ${PN}
+	fi
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]] ; then
+		einfo "See /etc/dehydrated/config for configuration."
+
+		use cron && einfo "After finishing setup you should enable the cronjob in /etc/cron.d/dehydrated."
+	fi
+}