summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'app-emacs/bbdb/bbdb-3.2.2a.ebuild')
-rw-r--r--app-emacs/bbdb/bbdb-3.2.2a.ebuild66
1 files changed, 66 insertions, 0 deletions
diff --git a/app-emacs/bbdb/bbdb-3.2.2a.ebuild b/app-emacs/bbdb/bbdb-3.2.2a.ebuild
new file mode 100644
index 000000000000..5f856b6fdaef
--- /dev/null
+++ b/app-emacs/bbdb/bbdb-3.2.2a.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp autotools
+
+DESCRIPTION="The Insidious Big Brother Database"
+HOMEPAGE="https://savannah.nongnu.org/projects/bbdb/"
+#SRC_URI="https://download.savannah.gnu.org/releases/${PN}/${P}.tar.gz"
+SRC_URI="https://git.savannah.nongnu.org/cgit/bbdb.git/snapshot/${P}.tar.gz"
+
+LICENSE="GPL-3+ FDL-1.3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris"
+IUSE="tex vm wanderlust"
+RESTRICT="test" #631700
+
+RDEPEND="vm? ( app-emacs/vm )
+ wanderlust? ( app-emacs/wanderlust )"
+BDEPEND="${RDEPEND}
+ sys-apps/texinfo"
+RDEPEND="${RDEPEND}
+ tex? ( virtual/latex-base )"
+
+SITEFILE="50${PN}-gentoo-3.2.el"
+TEXMF="/usr/share/texmf-site"
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ econf \
+ --with-lispdir="${EPREFIX}${SITELISP}/${PN}" \
+ "$(use_with vm vm-dir "${EPREFIX}${SITELISP}/vm")" \
+ "$(use_with wanderlust wl-dir "${EPREFIX}${SITELISP}/wl")"
+}
+
+src_compile() {
+ emake -C lisp
+ emake -C doc
+}
+
+src_install() {
+ emake -C lisp DESTDIR="${D}" install
+ emake -C doc DESTDIR="${D}" install
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+ dodoc AUTHORS ChangeLog NEWS README TODO
+
+ if use tex; then
+ insinto "${TEXMF}"/tex/latex/${PN}
+ doins tex/bbdb.sty
+ fi
+}
+
+pkg_postinst() {
+ elisp-site-regen
+ use tex && texconfig rehash
+}
+
+pkg_postrm() {
+ elisp-site-regen
+ use tex && texconfig rehash
+}