1 files changed, 39 insertions, 0 deletions
diff --git a/app-emacs/emms/emms-10.ebuild b/app-emacs/emms/emms-10.ebuild
new file mode 100644
index 000000000000..fc6756b89a2c
--- /dev/null
+++ b/app-emacs/emms/emms-10.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp toolchain-funcs
+
+DESCRIPTION="The Emacs Multimedia System"
+HOMEPAGE="https://www.gnu.org/software/emms/
+	https://www.emacswiki.org/emacs/EMMS"
+# Taken from https://elpa.gnu.org/packages/${P}.tar
+SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
+
+LICENSE="GPL-3+ FDL-1.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+RDEPEND="media-libs/taglib"
+DEPEND="${RDEPEND}"
+
+# EMMS can use almost anything for playing media files therefore the dependency
+# possibilities are so broad that we refrain from setting anything explicitly
+# in DEPEND/RDEPEND.
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_compile() {
+	emake CC="$(tc-getCC)" CXX="$(tc-getCXX)" \
+		all emms-print-metadata
+}
+
+src_install() {
+	elisp-install ${PN} *.el *.elc
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	doinfo doc/emms.info*
+	dobin src/emms-print-metadata
+	doman emms-print-metadata.1
+	dodoc AUTHORS NEWS README THANKGNU
+}