1 files changed, 46 insertions, 0 deletions
diff --git a/app-emacs/lsp-java/lsp-java-3.1.ebuild b/app-emacs/lsp-java/lsp-java-3.1.ebuild
new file mode 100644
index 000000000000..d67e027ae82a
--- /dev/null
+++ b/app-emacs/lsp-java/lsp-java-3.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+NEED_EMACS=25.1
+
+inherit elisp
+
+DESCRIPTION="Emacs Java IDE using Eclipse JDT Language Server"
+HOMEPAGE="https://emacs-lsp.github.io/lsp-java/"
+SRC_URI="https://github.com/emacs-lsp/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+KEYWORDS="~amd64"
+SLOT="0"
+RESTRICT="test"  # Tests are unnecessary, they run "build compile checkdoc lint"
+
+RDEPEND="
+	app-emacs/dap-mode
+	app-emacs/dash
+	app-emacs/f
+	app-emacs/ht
+	app-emacs/lsp-mode
+	app-emacs/markdown-mode
+	app-emacs/request
+	app-emacs/treemacs
+"
+BDEPEND="${RDEPEND}"
+
+DOCS=( README.md images )
+PATCHES=( "${FILESDIR}"/${PN}-icons.patch )
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	elisp_src_prepare
+
+	sed "s|@SITEETC@|${SITEETC}/${PN}|" -i ${PN}.el -i lsp-jt.el || die
+}
+
+src_install() {
+	elisp_src_install
+
+	insinto ${SITEETC}/${PN}
+	doins -r icons
+}