summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'app-emulation/xen/xen-4.16.0-r7.ebuild')
-rw-r--r--app-emulation/xen/xen-4.16.0-r7.ebuild190
1 files changed, 0 insertions, 190 deletions
diff --git a/app-emulation/xen/xen-4.16.0-r7.ebuild b/app-emulation/xen/xen-4.16.0-r7.ebuild
deleted file mode 100644
index 07e9855fc98..00000000000
--- a/app-emulation/xen/xen-4.16.0-r7.ebuild
+++ /dev/null
@@ -1,190 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} )
-
-inherit flag-o-matic mount-boot python-any-r1 toolchain-funcs
-
-MY_PV=${PV/_/-}
-MY_P=${PN}-${MY_PV}
-
-if [[ ${PV} == *9999 ]]; then
- inherit git-r3
- EGIT_REPO_URI="git://xenbits.xen.org/xen.git"
- SRC_URI=""
-else
- KEYWORDS="~amd64 ~arm -x86"
- UPSTREAM_VER=2
- SECURITY_VER=
- GENTOO_VER=
-
- [[ -n ${UPSTREAM_VER} ]] && \
- UPSTREAM_PATCHSET_URI="https://dev.gentoo.org/~dlan/distfiles/${P}-upstream-patches-${UPSTREAM_VER}.tar.xz
- https://github.com/hydrapolic/gentoo-dist/raw/master/xen/${P}-upstream-patches-${UPSTREAM_VER}.tar.xz"
- [[ -n ${SECURITY_VER} ]] && \
- SECURITY_PATCHSET_URI="https://dev.gentoo.org/~dlan/distfiles/${PN}-security-patches-${SECURITY_VER}.tar.xz"
- [[ -n ${GENTOO_VER} ]] && \
- GENTOO_PATCHSET_URI="https://dev.gentoo.org/~dlan/distfiles/${PN}-gentoo-patches-${GENTOO_VER}.tar.xz"
- SRC_URI="https://downloads.xenproject.org/release/xen/${MY_PV}/${MY_P}.tar.gz
- ${UPSTREAM_PATCHSET_URI}
- ${SECURITY_PATCHSET_URI}
- ${GENTOO_PATCHSET_URI}"
-fi
-
-DESCRIPTION="The Xen virtual machine monitor"
-HOMEPAGE="https://xenproject.org"
-LICENSE="GPL-2"
-SLOT="0"
-IUSE="+boot-symlinks debug efi flask"
-REQUIRED_USE="arm? ( debug )"
-
-DEPEND="${PYTHON_DEPS}
- efi? ( >=sys-devel/binutils-2.22[multitarget] )
- !efi? ( >=sys-devel/binutils-2.22 )
- flask? ( sys-apps/checkpolicy )"
-RDEPEND=""
-PDEPEND="~app-emulation/xen-tools-${PV}"
-
-# no tests are available for the hypervisor
-# prevent the silliness of /usr/lib/debug/usr/lib/debug files
-# prevent stripping of the debug info from the /usr/lib/debug/xen-syms
-RESTRICT="test splitdebug strip"
-
-# Approved by QA team in bug #144032
-QA_WX_LOAD="boot/xen-syms-${PV}"
-
-S="${WORKDIR}/${MY_P}"
-
-pkg_setup() {
- python-any-r1_pkg_setup
- if [[ -z ${XEN_TARGET_ARCH} ]]; then
- if use amd64; then
- export XEN_TARGET_ARCH="x86_64"
- elif use arm; then
- export XEN_TARGET_ARCH="arm32"
- elif use arm64; then
- export XEN_TARGET_ARCH="arm64"
- else
- die "Unsupported architecture!"
- fi
- fi
-}
-
-src_prepare() {
- # Upstream's patchset
- [[ -n ${UPSTREAM_VER} ]] && eapply "${WORKDIR}"/patches-upstream
-
- # Security patchset
- if [[ -n ${SECURITY_VER} ]]; then
- einfo "Try to apply Xen Security patch set"
- # apply main xen patches
- # Two parallel systems, both work side by side
- # Over time they may concdense into one. This will suffice for now
- source "${WORKDIR}"/patches-security/${PV}.conf
-
- local i
- for i in ${XEN_SECURITY_MAIN}; do
- eapply "${WORKDIR}"/patches-security/xen/$i
- done
- fi
-
- # Gentoo's patchset
- [[ -n ${GENTOO_VER} ]] && eapply "${WORKDIR}"/patches-gentoo
-
- eapply "${FILESDIR}"/${PN}-4.16-efi.patch
-
- # Symlinks do not work on fat32 volumes # 829765
- if ! use boot-symlinks || use efi; then
- eapply "${FILESDIR}"/${PN}-4.16-no-symlink.patch
- fi
-
- # Workaround new gcc-11 options
- sed -e '/^CFLAGS/s/-Werror//g' -i xen/Makefile || die
-
- # Drop .config
- sed -e '/-include $(XEN_ROOT)\/.config/d' -i Config.mk || die "Couldn't drop"
-
- if use efi; then
- export EFI_VENDOR="gentoo"
- export EFI_MOUNTPOINT="/boot"
- fi
-
- default
-}
-
-xen_make() {
- # Setting clang to either 'y' or 'n' tells Xen's build system
- # whether or not clang is used.
- local clang=n
- if tc-is-clang; then
- clang=y
- fi
-
- # Send raw LDFLAGS so that --as-needed works
- emake \
- V=1 \
- LDFLAGS="$(raw-ldflags)" \
- HOSTCC="$(tc-getBUILD_CC)" \
- HOSTCXX="$(tc-getBUILD_CXX)" \
- clang="${clang}" \
- "$@"
-}
-
-src_configure() {
- cd xen || die
-
- touch gentoo-config || die
- if use arm; then
- echo "CONFIG_EARLY_PRINTK=sun7i" >> gentoo-config || die
- fi
- if use debug; then
- cat <<-EOF >> gentoo-config || die
- CONFIG_DEBUG=y
- CONFIG_CRASH_DEBUG=y
-EOF
- fi
- if use flask; then
- echo "CONFIG_XSM=y" >> gentoo-config || die
- fi
-
- # remove flags
- unset CFLAGS
-
- tc-ld-disable-gold # Bug 700374
-
- xen_make KCONFIG_ALLCONFIG=gentoo-config alldefconfig
-}
-
-src_compile() {
- xen_make -C xen
-}
-
-src_install() {
- # The 'make install' doesn't 'mkdir -p' the subdirs
- if use efi; then
- mkdir -p "${D}"${EFI_MOUNTPOINT}/efi/${EFI_VENDOR} || die
- fi
-
- xen_make DESTDIR="${D}" -C xen install
-
- # make install likes to throw in some extra EFI bits if it built
- use efi || rm -rf "${D}/usr/$(get_libdir)/efi"
-}
-
-pkg_postinst() {
- elog "Official Xen Guide:"
- elog " https://wiki.gentoo.org/wiki/Xen"
-
- use efi && einfo "The efi executable is installed in /boot/efi/gentoo"
-
- ewarn
- ewarn "Xen 4.12+ changed the default scheduler to credit2 which can cause"
- ewarn "domU lockups on multi-cpu systems. The legacy credit scheduler seems"
- ewarn "to work fine."
- ewarn
- ewarn "Add sched=credit to xen command line options to use the legacy scheduler."
- ewarn
- ewarn "https://wiki.gentoo.org/wiki/Xen#Xen_domU_hanging_with_Xen_4.12.2B"
-}