summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'app-misc/pal/pal-0.4.3-r2.ebuild')
-rw-r--r--app-misc/pal/pal-0.4.3-r2.ebuild60
1 files changed, 60 insertions, 0 deletions
diff --git a/app-misc/pal/pal-0.4.3-r2.ebuild b/app-misc/pal/pal-0.4.3-r2.ebuild
new file mode 100644
index 00000000000..f3c73091dfc
--- /dev/null
+++ b/app-misc/pal/pal-0.4.3-r2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit prefix toolchain-funcs
+
+DESCRIPTION="Command-line calendar program"
+HOMEPAGE="http://palcal.sourceforge.net/"
+SRC_URI="mirror://sourceforge/palcal/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~x86 ~x86-interix ~amd64-linux ~x86-linux ~x86-macos"
+IUSE="nls"
+
+RDEPEND="
+ >=dev-libs/glib-2.0
+ nls? ( virtual/libintl )
+ sys-libs/ncurses:0
+ sys-libs/readline:0
+"
+DEPEND="
+ ${RDEPEND}
+ nls? ( sys-devel/gettext )
+ virtual/pkgconfig
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PV}-strip.patch
+ "${FILESDIR}"/${PV}-ldflags.patch
+ "${FILESDIR}"/${P}-pkg_config.patch
+ "${FILESDIR}"/${P}-prefix.patch
+ "${FILESDIR}"/fix-Wformat-security-errors.patch
+)
+
+src_prepare() {
+ default
+
+ cd src || die "failed to change to the src directory"
+ eprefixify Makefile.defs input.c Makefile
+ sed -i -e 's/ -o root//g' {.,convert}/Makefile || die
+ tc-export PKG_CONFIG
+}
+
+src_compile() {
+ cd src || die "failed to change to the src directory"
+ emake CC="$(tc-getCC)" OPT="${CFLAGS}" LDOPT="${LDFLAGS}"
+}
+
+src_install() {
+ dodoc ChangeLog doc/example.css
+
+ cd src || die "failed to change to the src directory"
+ emake DESTDIR="${D}" install-man install-bin install-share
+
+ if use nls; then
+ emake DESTDIR="${D}" install-mo
+ fi
+}