1 files changed, 31 insertions, 0 deletions
diff --git a/app-misc/tty-clock/tty-clock-2.3.ebuild b/app-misc/tty-clock/tty-clock-2.3.ebuild
new file mode 100644
index 000000000000..4118f7d9021e
--- /dev/null
+++ b/app-misc/tty-clock/tty-clock-2.3.ebuild
@@ -0,0 +1,31 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Displays a simple digital clock on the terminal"
+HOMEPAGE="https://github.com/xorg62/tty-clock"
+SRC_URI="https://github.com/xorg62/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64"
+
+DEPEND="sys-libs/ncurses:=[unicode(+)]"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_compile() {
+	# makefile does something with ncurses-config and calls old version
+	# let's just build it manually
+	$(tc-getCC) -Wall ${CFLAGS} ${PN//-/}.c \
+		$($(tc-getPKG_CONFIG) --libs ncursesw) \
+		-o ${PN} ${LDFLAGS} || die "Failed to build ${PN}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+	einstalldocs
+}