summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'app-portage/gentoolkit/gentoolkit-0.3.2-r1.ebuild')
-rw-r--r--app-portage/gentoolkit/gentoolkit-0.3.2-r1.ebuild77
1 files changed, 77 insertions, 0 deletions
diff --git a/app-portage/gentoolkit/gentoolkit-0.3.2-r1.ebuild b/app-portage/gentoolkit/gentoolkit-0.3.2-r1.ebuild
new file mode 100644
index 00000000000..75851ddca95
--- /dev/null
+++ b/app-portage/gentoolkit/gentoolkit-0.3.2-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+PYTHON_COMPAT=(python{2_7,3_3,3_4,3_5} pypy)
+PYTHON_REQ_USE="xml(+),threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of administration scripts for Gentoo"
+HOMEPAGE="https://www.gentoo.org/proj/en/portage/tools/index.xml"
+SRC_URI="http://dev.gentoo.org/~dolsen/releases/gentoolkit/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+DEPEND="sys-apps/portage[${PYTHON_USEDEP}]"
+RDEPEND="${DEPEND}
+ !<=app-portage/gentoolkit-dev-0.2.7
+ || ( >=sys-apps/coreutils-8.15 app-misc/realpath sys-freebsd/freebsd-bin )
+ sys-apps/gawk
+ sys-apps/gentoo-functions
+ sys-apps/grep"
+
+PATCHES=(
+ "${FILESDIR}"/${PV}-helpers.py-589686.patch
+)
+
+python_prepare_all() {
+ python_setup
+ echo VERSION="${PVR}" "${PYTHON}" setup.py set_version
+ VERSION="${PVR}" "${PYTHON}" setup.py set_version
+ distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+
+ # remove on Gentoo Prefix platforms where it's broken anyway
+ if use prefix; then
+ elog "The revdep-rebuild command is removed, the preserve-libs"
+ elog "feature of portage will handle issues."
+ rm "${ED}"/usr/bin/revdep-rebuild*
+ rm "${ED}"/usr/share/man/man1/revdep-rebuild.1
+ rm -rf "${ED}"/etc/revdep-rebuild
+ rm -rf "${ED}"/var
+ fi
+}
+
+pkg_postinst() {
+ # Create cache directory for revdep-rebuild
+ mkdir -p -m 0755 "${EROOT%/}"/var/cache
+ mkdir -p -m 0700 "${EROOT%/}"/var/cache/revdep-rebuild
+
+ # Only show the elog information on a new install
+ if [[ ! ${REPLACING_VERSIONS} ]]; then
+ elog
+ elog "For further information on gentoolkit, please read the gentoolkit"
+ elog "guide: https://www.gentoo.org/doc/en/gentoolkit.xml"
+ elog
+ elog "Another alternative to equery is app-portage/portage-utils"
+ elog
+ elog "Additional tools that may be of interest:"
+ elog
+ elog " app-admin/eclean-kernel"
+ elog " app-portage/diffmask"
+ elog " app-portage/flaggie"
+ elog " app-portage/install-mask"
+ elog " app-portage/portpeek"
+ elog " app-portage/smart-live-rebuild"
+ fi
+}