summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'app-text/yodl/yodl-4.02.01.ebuild')
-rw-r--r--app-text/yodl/yodl-4.02.01.ebuild48
1 files changed, 48 insertions, 0 deletions
diff --git a/app-text/yodl/yodl-4.02.01.ebuild b/app-text/yodl/yodl-4.02.01.ebuild
new file mode 100644
index 00000000000..3ea825807fc
--- /dev/null
+++ b/app-text/yodl/yodl-4.02.01.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="Your Own Document Language: a pre-document language and tools to process it"
+HOMEPAGE="https://fbb-git.gitlab.io/yodl/ https://gitlab.com/fbb-git/yodl"
+SRC_URI="https://gitlab.com/fbb-git/${PN}/-/archive/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+DEPEND=">=dev-util/icmake-8.00.00"
+
+S=${WORKDIR}/${P}/${PN}
+
+src_prepare() {
+ sed -e "/DOC.* =/s/yodl\(-doc\)\?/${PF}/" \
+ -e "/COMPILER =/s/gcc/$(tc-getCC)/" \
+ -e "/CXX =/s/g++/$(tc-getCXX)/" \
+ -i INSTALL.im || die
+ sed -i "s/g++/$(tc-getCXX)/" verbinsert/icmconf || die
+
+ sed -e "s/ar r /$(tc-getAR) r /" \
+ -e "s/ranlib/$(tc-getRANLIB)/" \
+ -i icmake/stdcompile || die
+
+ default
+}
+
+src_compile() {
+ ./build programs || die
+ ./build macros || die
+ ./build man || die
+ use doc && { ./build manual || die ; }
+}
+
+src_install() {
+ ./build install programs "${ED}" || die
+ ./build install macros "${ED}" || die
+ ./build install man "${ED}" || die
+ ./build install docs "${ED}" || die
+ use doc && { ./build install manual "${ED}" || die ; }
+}