1 files changed, 57 insertions, 0 deletions
diff --git a/dev-java/xerces/xerces-2.12.0-r1.ebuild b/dev-java/xerces/xerces-2.12.0-r1.ebuild
new file mode 100644
index 000000000000..d91487c5f49d
--- /dev/null
+++ b/dev-java/xerces/xerces-2.12.0-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+JAVA_PKG_IUSE="doc source"
+MAVEN_ID="xerces:xercesImpl:2.12.0"
+
+inherit java-pkg-2 java-pkg-simple
+
+MY_PN="xercesImpl"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Xerces Java XML parser"
+HOMEPAGE="https://xml.apache.org/xerces2-j/index.html"
+SRC_URI="https://repo1.maven.org/maven2/xerces/${MY_PN}/${PV}/${MY_P}-sources.jar -> ${P}.jar"
+
+LICENSE="Apache-2.0"
+SLOT="2"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+CDEPEND="
+	dev-java/xjavac:1
+	dev-java/xml-commons-resolver:0
+	dev-java/xml-commons-external:1.4"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.6"
+
+DEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.6"
+
+JAVA_SRC_DIR="org"
+JAVA_RESOURCE_DIRS="resources"
+
+JAVA_GENTOO_CLASSPATH="
+	xjavac-1
+	xml-commons-resolver
+	xml-commons-external-1.4"
+
+S="${WORKDIR}"
+
+PATCHES=(
+	"${FILESDIR}/${P}-overrides.patch"
+)
+
+src_prepare() {
+	default
+	mkdir "${JAVA_RESOURCE_DIRS}" || die
+	cp -r "${JAVA_SRC_DIR}" "${JAVA_RESOURCE_DIRS}" || die
+	find "${JAVA_RESOURCE_DIRS}" -type f -name '*.java' -exec rm -rf {} + || die
+	rm "${JAVA_RESOURCE_DIRS}"/org/apache/xerces/{dom/org.apache.xerces.dom.DOMImplementationSourceImpl,xs/datatypes/package.html,parsers/org*} || die
+
+	java-pkg-2_src_prepare
+}