1 files changed, 47 insertions, 0 deletions
diff --git a/dev-libs/c-blosc/c-blosc-1.20.1.ebuild b/dev-libs/c-blosc/c-blosc-1.20.1.ebuild
new file mode 100644
index 000000000000..894b71680371
--- /dev/null
+++ b/dev-libs/c-blosc/c-blosc-1.20.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Blocking, shuffling and lossless compression library"
+HOMEPAGE="https://www.blosc.org/"
+SRC_URI="https://github.com/Blosc/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="+lz4 +snappy test zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	lz4? ( >=app-arch/lz4-1.7.5:= )
+	snappy? ( app-arch/snappy )
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	cmake_src_prepare
+	# remove bundled libs
+	rm -rf internal-complibs || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_STATIC=OFF
+		-DBUILD_TESTS=$(usex test)
+		-DBUILD_BENCHMARKS=OFF
+		-DBUILD_FUZZERS=OFF
+		-DDEACTIVATE_LZ4=$(usex !lz4)
+		-DDEACTIVATE_SNAPPY=$(usex !snappy)
+		-DDEACTIVATE_ZLIB=$(usex !zlib)
+		-DDEACTIVATE_ZSTD=$(usex !zstd)
+		-DPREFER_EXTERNAL_LZ4=ON
+		# snappy is always external
+		-DPREFER_EXTERNAL_ZLIB=ON
+		-DPREFER_EXTERNAL_ZSTD=ON
+	)
+	cmake_src_configure
+}