1 files changed, 77 insertions, 0 deletions
diff --git a/dev-libs/librep/librep-0.92.5.ebuild b/dev-libs/librep/librep-0.92.5.ebuild
new file mode 100644
index 000000000000..d5d6c92772f9
--- /dev/null
+++ b/dev-libs/librep/librep-0.92.5.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit elisp-common eutils flag-o-matic
+
+DESCRIPTION="Shared library implementing a Lisp dialect"
+HOMEPAGE="http://librep.sourceforge.net/"
+SRC_URI="http://download.tuxfamily.org/librep/${PN}_${PV}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="emacs readline"
+
+RDEPEND="
+	>=sys-libs/gdbm-1.8.0
+	emacs? ( virtual/emacs )
+	readline? ( sys-libs/readline:0= )
+"
+DEPEND="${RDEPEND}
+	sys-apps/texinfo
+	app-arch/xz-utils
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.92.0-disable-elisp.patch"
+)
+
+S="${WORKDIR}/${PN}_${PV}"
+
+src_prepare() {
+	# fix #570072 by restoring pre-GCC5 inline semantics
+	append-cflags -std=gnu89
+	default
+}
+
+src_configure() {
+	econf \
+		--libexecdir=/usr/$(get_libdir) \
+		--without-gmp \
+		--without-ffi \
+		--disable-static \
+		$(use_with readline)
+}
+
+src_compile() {
+	default
+
+	if use emacs; then
+		elisp-compile rep-debugger.el || die "elisp-compile failed"
+	fi
+}
+
+src_install() {
+	default
+	prune_libtool_files --modules
+
+	docinto doc
+	dodoc doc/*
+
+	if use emacs; then
+		elisp-install ${PN} rep-debugger.{el,elc} || die "elisp-install failed"
+		elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el" \
+			|| die "elisp-site-file-install failed"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}