1 files changed, 63 insertions, 0 deletions
diff --git a/dev-libs/log4cpp/log4cpp-1.1.3-r1.ebuild b/dev-libs/log4cpp/log4cpp-1.1.3-r1.ebuild
new file mode 100644
index 000000000000..e84b5498cc10
--- /dev/null
+++ b/dev-libs/log4cpp/log4cpp-1.1.3-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="C++ classes for flexible logging to files, syslog and other destinations"
+HOMEPAGE="http://log4cpp.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="LGPL-2.1"
+SLOT="0/5"
+KEYWORDS="~amd64 ~arm ~ppc ~riscv ~s390 ~x86"
+IUSE="doc static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="doc? ( app-doc/doxygen )"
+
+PATCHES=(
+	"${FILESDIR}"/1.0-doc_install_path.patch
+	"${FILESDIR}"/1.0-gcc43.patch
+	"${FILESDIR}"/1.0-asneeded.patch
+	"${FILESDIR}"/${PN}-1.1-cmath-fix.patch
+	"${FILESDIR}"/${PN}-1.1-automake-1.13.patch
+	"${FILESDIR}"/${PN}-1.1-glibc-2.31.patch
+	"${FILESDIR}"/${PN}-1.1.3-fix-version.patch
+)
+
+MULTILIB_CHOST_TOOLS=(
+	/usr/bin/log4cpp-config
+)
+
+src_prepare() {
+	default
+
+	mv configure.{in,ac} || die
+
+	# Build tests conditionally
+	if ! use test; then
+		sed -i -e '/^SUBDIRS/s/ tests//' Makefile.am || die
+	fi
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	# Bashisms call configure tests to malfunction / config.h to be misgenerated
+	# which then causes a build failure later on in the package (w/ GCC 12,
+	# anyway).
+	CONFIG_SHELL="${BROOT}"/bin/bash ECONF_SOURCE="${S}" econf \
+		--without-idsa \
+		$(use_enable doc doxygen) \
+		$(use_enable static-libs static)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	# Package installs .pc files
+	find "${D}" -name '*.la' -delete || die
+}