1 files changed, 51 insertions, 0 deletions
diff --git a/dev-libs/ptexenc/ptexenc-1.3.4_p20160523.ebuild b/dev-libs/ptexenc/ptexenc-1.3.4_p20160523.ebuild
new file mode 100644
index 000000000000..df76f2ccab92
--- /dev/null
+++ b/dev-libs/ptexenc/ptexenc-1.3.4_p20160523.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit libtool
+
+DESCRIPTION="Library for Japanese pTeX providing a better way of handling character encodings"
+HOMEPAGE="http://tutimura.ath.cx/ptexlive/?ptexenc"
+SRC_URI="mirror://gentoo/texlive-${PV#*_p}-source.tar.xz"
+# http://tutimura.ath.cx/~nob/tex/ptexlive/ptexenc/${P}.tar.xz
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~ppc-macos ~x86-macos"
+IUSE="iconv static-libs"
+
+DEPEND="iconv? ( virtual/libiconv )
+	dev-libs/kpathsea"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/texlive-${PV#*_p}-source/texk/${PN}
+
+src_prepare() {
+	default
+
+	# https://bugs.gentoo.org/show_bug.cgi?id=377141
+	sed -i '/^LIBS/s:@LIBS@:@LIBS@ @KPATHSEA_LIBS@:' "${S}"/Makefile.in || die
+
+	cd "${WORKDIR}/texlive-${PV#*_p}-source"
+	S="${WORKDIR}/texlive-${PV#*_p}-source" elibtoolize #sane .so versionning on gfbsd
+}
+
+src_configure() {
+	econf \
+		--with-system-kpathsea \
+		$(use_enable static-libs static) \
+		$(use_enable iconv kanji-iconv)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	find "${D}" -name '*.la' -delete
+
+	insinto /usr/include/ptexenc
+	doins ptexenc/unicode-jp.h
+	use iconv && doins ptexenc/kanjicnv.h
+
+	dodoc ChangeLog README
+}