1 files changed, 48 insertions, 0 deletions
diff --git a/dev-libs/ptexenc/ptexenc-1.3.9_p20210325-r1.ebuild b/dev-libs/ptexenc/ptexenc-1.3.9_p20210325-r1.ebuild
new file mode 100644
index 000000000000..ccaf4a3f4df8
--- /dev/null
+++ b/dev-libs/ptexenc/ptexenc-1.3.9_p20210325-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit libtool
+
+DESCRIPTION="Library for Japanese pTeX providing a better way of handling character encodings"
+HOMEPAGE="http://tutimura.ath.cx/ptexlive/?ptexenc"
+SRC_URI="https://dev.gentoo.org/~sam/distfiles/texlive/texlive-${PV#*_p}-source.tar.xz"
+S="${WORKDIR}/texlive-${PV#*_p}-source/texk/${PN}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~ppc-macos ~x64-macos"
+IUSE="iconv"
+
+DEPEND="
+	dev-libs/kpathsea:=
+	iconv? ( virtual/libiconv )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+
+	# https://bugs.gentoo.org/show_bug.cgi?id=377141
+	sed -i '/^LIBS/s:@LIBS@:@LIBS@ @KPATHSEA_LIBS@:' Makefile.in || die
+
+	cd "${WORKDIR}/texlive-${PV#*_p}-source" || die
+	S="${WORKDIR}/texlive-${PV#*_p}-source" elibtoolize #sane .so versionning on gfbsd
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--with-system-kpathsea \
+		$(use_enable iconv kanji-iconv)
+}
+
+src_install() {
+	default
+
+	insinto /usr/include/ptexenc
+	doins ptexenc/unicode-jp.h
+	use iconv && doins ptexenc/kanjicnv.h
+
+	find "${ED}" -name '*.la' -delete || die
+}