summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'dev-python/Babel/Babel-2.0.ebuild')
-rw-r--r--dev-python/Babel/Babel-2.0.ebuild49
1 files changed, 49 insertions, 0 deletions
diff --git a/dev-python/Babel/Babel-2.0.ebuild b/dev-python/Babel/Babel-2.0.ebuild
new file mode 100644
index 00000000000..04989246dc9
--- /dev/null
+++ b/dev-python/Babel/Babel-2.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A collection of tools for internationalizing Python applications"
+HOMEPAGE="http://babel.edgewall.org/ http://pypi.python.org/pypi/Babel"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+RDEPEND="dev-python/pytz[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${DEPEND}
+ doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+ test? ( >=dev-python/pytest-2.3.5[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+ # Make the tests use implementation-specific datadir,
+ # because they try to write in it.
+ sed -e '/datadir =/s:os\.path\.dirname(__file__):os.environ["BUILD_DIR"]:' \
+ -i tests/messages/test_frontend.py || die
+ sed -e '/^intersphinx_mapping/,+3d' -i docs/conf.py || die
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ # Create implementation-specific datadir for tests.
+ cp -R -l tests/messages/data "${BUILD_DIR}"/ || die
+ export BUILD_DIR
+ py.test || die
+}
+
+python_compile_all() {
+ use doc && emake -C docs html
+}
+
+python_install_all() {
+ use doc && local HTML_DOCS=( docs/_build/html/. )
+ distutils-r1_python_install_all
+}