1 files changed, 55 insertions, 0 deletions
diff --git a/dev-python/Babel/Babel-2.7.0.ebuild b/dev-python/Babel/Babel-2.7.0.ebuild
new file mode 100644
index 000000000000..94515713987a
--- /dev/null
+++ b/dev-python/Babel/Babel-2.7.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7,8}} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of tools for internationalizing Python applications"
+HOMEPAGE="http://babel.pocoo.org/ https://pypi.org/project/Babel/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${DEPEND}
+	doc? ( $(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]') )
+	test? ( dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_check_deps() {
+	use doc || return 0
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+python_prepare_all() {
+	# Make the tests use implementation-specific datadir,
+	# because they try to write in it.
+	sed -e '/datadir =/s:os\.path\.dirname(__file__):os.environ["BUILD_DIR"]:' \
+		-i tests/messages/test_frontend.py || die
+	sed -e '/^intersphinx_mapping/,+3d' -i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	local -x TZ=UTC
+
+	# Create implementation-specific datadir for tests.
+	cp -R -l tests/messages/data "${BUILD_DIR}"/ || die
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}