summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'dev-python/boto/boto-2.38.0.ebuild')
-rw-r--r--dev-python/boto/boto-2.38.0.ebuild48
1 files changed, 48 insertions, 0 deletions
diff --git a/dev-python/boto/boto-2.38.0.ebuild b/dev-python/boto/boto-2.38.0.ebuild
new file mode 100644
index 00000000000..3bc86070a3c
--- /dev/null
+++ b/dev-python/boto/boto-2.38.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="Amazon Web Services API"
+HOMEPAGE="https://github.com/boto/boto http://pypi.python.org/pypi/boto"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+ test? ( dev-python/nose[${PYTHON_USEDEP}] )
+ doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+# requires Amazon Web Services keys to pass some tests
+RESTRICT="test"
+
+python_test() {
+ "${PYTHON}" tests/test.py -v || die "Tests fail with ${EPYTHON}"
+}
+
+python_prepare_all() {
+ # Prevent un-needed d'loading
+ sed -e "s/, 'sphinx.ext.intersphinx'//" -i docs/source/conf.py || die
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ if use doc; then
+ # Appease the doc build and supply a file for _static
+ # the usual emake -C docs doesn't work under this authorship
+ cd docs && mkdir source/_static || die
+ emake html
+ fi
+}
+
+python_install_all() {
+ use doc && local HTML_DOCS=( docs/build/html/. )
+ distutils-r1_python_install_all
+}