summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'dev-python/flask-sqlalchemy/flask-sqlalchemy-1.0-r1.ebuild')
-rw-r--r--dev-python/flask-sqlalchemy/flask-sqlalchemy-1.0-r1.ebuild51
1 files changed, 51 insertions, 0 deletions
diff --git a/dev-python/flask-sqlalchemy/flask-sqlalchemy-1.0-r1.ebuild b/dev-python/flask-sqlalchemy/flask-sqlalchemy-1.0-r1.ebuild
new file mode 100644
index 00000000000..3838e5f3722
--- /dev/null
+++ b/dev-python/flask-sqlalchemy/flask-sqlalchemy-1.0-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+MY_PN="Flask-SQLAlchemy"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="SQLAlchemy support for Flask applications"
+HOMEPAGE="http://pypi.python.org/pypi/Flask-SQLAlchemy"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND=">=dev-python/flask-0.10[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ dev-python/sqlalchemy[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+ doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+# Patch out un-needed d'loading of obj.inv files in doc build
+PATCHES=( "${FILESDIR}"/mapping.patch )
+
+# Req'd for tests in py3
+DISTUTILS_IN_SOURCE_BUILD=1
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+ use doc && esetup.py build_sphinx
+}
+
+python_test() {
+ #https://github.com/mitsuhiko/flask-sqlalchemy/issues/128
+ if python_is_python3; then
+ sed -e s':test_model_signals:_&:' -i test_sqlalchemy.py || die
+ fi
+ esetup.py test
+}
+
+python_install_all() {
+ use doc && HTML_DOCS=( docs/_build/html/. )
+ distutils-r1_python_install_all
+}