1 files changed, 36 insertions, 0 deletions
diff --git a/dev-python/grpcio-tools/grpcio-tools-1.32.0.ebuild b/dev-python/grpcio-tools/grpcio-tools-1.32.0.ebuild
new file mode 100644
index 000000000000..1cd0831159e4
--- /dev/null
+++ b/dev-python/grpcio-tools/grpcio-tools-1.32.0.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1 multiprocessing prefix
+
+DESCRIPTION="Protobuf code generator for gRPC"
+HOMEPAGE="https://grpc.io"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	~dev-python/grpcio-${PV}[${PYTHON_USEDEP}]
+	dev-python/protobuf-python[${PYTHON_USEDEP}]
+"
+
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}/1.32.0-setup.py-respect-CC-variable-in-latomic-test.patch" )
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+	hprefixify setup.py
+}
+
+python_configure_all() {
+	export GRPC_PYTHON_BUILD_WITH_CYTHON=1
+	export GRPC_PYTHON_BUILD_EXT_COMPILER_JOBS="$(makeopts_jobs)"
+}