1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/markdown/markdown-3.3.4.ebuild b/dev-python/markdown/markdown-3.3.4.ebuild
new file mode 100644
index 000000000000..2f439b137c6e
--- /dev/null
+++ b/dev-python/markdown/markdown-3.3.4.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python implementation of the markdown markup language"
+HOMEPAGE="
+	https://python-markdown.github.io/
+	https://pypi.org/project/Markdown/
+	https://github.com/Python-Markdown/markdown"
+SRC_URI="mirror://pypi/M/${PN^}/${P^}.tar.gz"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="doc"
+
+# importlib_metadata is only necessary for <python:3.8 according to setup.py
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/importlib_metadata[${PYTHON_USEDEP}]
+	' python3_{6,7} pypy3)
+"
+BDEPEND="
+	test? (
+		dev-python/pygments[${PYTHON_USEDEP}]
+		dev-python/pytidylib[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests unittest
+
+python_install_all() {
+	use doc && dodoc -r docs/
+
+	distutils-r1_python_install_all
+}