1 files changed, 57 insertions, 0 deletions
diff --git a/dev-python/nbclient/nbclient-0.7.4.ebuild b/dev-python/nbclient/nbclient-0.7.4.ebuild
new file mode 100644
index 000000000000..a634386d779a
--- /dev/null
+++ b/dev-python/nbclient/nbclient-0.7.4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A client library for executing Jupyter notebooks"
+HOMEPAGE="
+	https://nbclient.readthedocs.io/en/latest/
+	https://github.com/jupyter/nbclient/
+	https://pypi.org/project/nbclient/
+"
+SRC_URI="
+	https://github.com/jupyter/nbclient/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/jupyter-client-6.1.12[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-5.1.0[${PYTHON_USEDEP}]
+	>=dev-python/nbformat-5.0[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+		dev-python/xmltodict[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	nbclient/tests/test_client.py::test_many_parallel_notebooks
+	'nbclient/tests/test_client.py::test_run_all_notebooks[Interrupt.ipynb-opts6]'
+)
+
+python_test() {
+	# The tests run the pydevd debugger, the debugger prints a warning
+	# in python3.11 when frozen modules are being used.
+	# This warning makes the tests fail, silence it.
+	PYDEVD_DISABLE_FILE_VALIDATION=1 epytest
+}