summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'dev-python/pgspecial/pgspecial-1.13.1-r1.ebuild')
-rw-r--r--dev-python/pgspecial/pgspecial-1.13.1-r1.ebuild47
1 files changed, 47 insertions, 0 deletions
diff --git a/dev-python/pgspecial/pgspecial-1.13.1-r1.ebuild b/dev-python/pgspecial/pgspecial-1.13.1-r1.ebuild
new file mode 100644
index 00000000000..d853eb86807
--- /dev/null
+++ b/dev-python/pgspecial/pgspecial-1.13.1-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python implementation of PostgreSQL meta commands"
+HOMEPAGE="https://github.com/dbcli/pgspecial"
+SRC_URI="https://github.com/dbcli/pgspecial/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD MIT"
+SLOT="0"
+KEYWORDS="amd64 x86"
+
+RDEPEND="
+ >=dev-python/click-4.1[${PYTHON_USEDEP}]
+ >=dev-python/configobj-5.0.6[${PYTHON_USEDEP}]
+ >=dev-python/psycopg-2.7.4:2[${PYTHON_USEDEP}]
+ >=dev-python/sqlparse-0.1.19[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? ( >=dev-db/postgresql-8.1[server] )
+"
+
+distutils_enable_tests pytest
+
+DOCS=( License.txt README.rst changelog.rst )
+
+src_test() {
+ local db=${T}/pgsql
+
+ initdb --username=postgres -D "${db}" || die
+ # TODO: random port
+ pg_ctl -w -D "${db}" start \
+ -o "-h '127.0.0.1' -p 5432 -k '${T}'" || die
+ psql -h "${T}" -U postgres -d postgres \
+ -c "ALTER ROLE postgres WITH PASSWORD 'postgres';" || die
+ createdb -h "${T}" -U postgres _test_db || die
+
+ distutils-r1_src_test
+
+ pg_ctl -w -D "${db}" stop || die
+}