1 files changed, 52 insertions, 0 deletions
diff --git a/dev-python/pymdown-extensions/pymdown-extensions-9.0.ebuild b/dev-python/pymdown-extensions/pymdown-extensions-9.0.ebuild
new file mode 100644
index 000000000000..8ed924a3f6a8
--- /dev/null
+++ b/dev-python/pymdown-extensions/pymdown-extensions-9.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	dev-python/mkdocs-git-revision-date-localized-plugin
+	dev-python/mkdocs-minify-plugin
+	dev-python/mkdocs-material
+	dev-python/pymdown-lexers
+	dev-python/pyspelling
+"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="Extensions for Python Markdown"
+HOMEPAGE="
+	https://github.com/facelessuser/pymdown-extensions/
+	https://pypi.org/project/pymdown-extensions/
+"
+SRC_URI="https://github.com/facelessuser/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+RDEPEND=">=dev-python/markdown-3.2[${PYTHON_USEDEP}]"
+
+BDEPEND="
+	test? (
+		dev-python/pygments[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# mkdocs-git-revision-date-localized-plugin needs git repo
+	if use doc; then
+		git init || die
+		git config --global user.email "you@example.com" || die
+		git config --global user.name "Your Name" || die
+		git add . || die
+		git commit -m 'init' || die
+	fi
+
+	distutils-r1_python_prepare_all
+}