1 files changed, 44 insertions, 0 deletions
diff --git a/dev-python/rich/rich-12.4.1.ebuild b/dev-python/rich/rich-12.4.1.ebuild
new file mode 100644
index 000000000000..e83ce3f6aa64
--- /dev/null
+++ b/dev-python/rich/rich-12.4.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for renrering rich text, tables, etc. to the terminal"
+HOMEPAGE="https://github.com/Textualize/rich"
+SRC_URI="
+	https://github.com/Textualize/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/commonmark[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.8)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x COLUMNS=80
+	local EPYTEST_DESELECT=(
+		# broken with =dev-python/pygments-2.12.0
+		tests/test_console.py::test_size_can_fall_back_to_std_descriptors
+	)
+	epytest -p no:pytest-qt
+}
+
+pkg_postinst() {
+	optfeature "integration with HTML widgets for Jupyter" dev-python/ipywidgets
+}