1 files changed, 47 insertions, 0 deletions
diff --git a/dev-python/thriftpy2/thriftpy2-0.4.16.ebuild b/dev-python/thriftpy2/thriftpy2-0.4.16.ebuild
new file mode 100644
index 000000000000..856239dd1ed6
--- /dev/null
+++ b/dev-python/thriftpy2/thriftpy2-0.4.16.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Pure python approach of Apache Thrift"
+HOMEPAGE="
+	https://github.com/Thriftpy/thriftpy2/
+	https://pypi.org/project/thriftpy2/
+"
+SRC_URI="
+	https://github.com/Thriftpy/thriftpy2/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/ply[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/tornado[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		tests/test_tornado.py::TornadoRPCTestCase::test_asynchronous_exception
+		tests/test_tornado.py::TornadoRPCTestCase::test_asynchronous_result
+	)
+
+	cd tests || die
+	epytest
+}