summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'dev-python/zc-lockfile')
-rw-r--r--dev-python/zc-lockfile/zc-lockfile-2.0-r1.ebuild47
-rw-r--r--dev-python/zc-lockfile/zc-lockfile-2.0.ebuild46
2 files changed, 47 insertions, 46 deletions
diff --git a/dev-python/zc-lockfile/zc-lockfile-2.0-r1.ebuild b/dev-python/zc-lockfile/zc-lockfile-2.0-r1.ebuild
new file mode 100644
index 00000000000..603b85c2ee9
--- /dev/null
+++ b/dev-python/zc-lockfile/zc-lockfile-2.0-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${PN/-/.}-${PV}
+DESCRIPTION="Basic inter-process locks"
+HOMEPAGE="
+ https://github.com/zopefoundation/zc.lockfile/
+ https://pypi.org/project/zc.lockfile/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN/-/.}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ~ppc64 ~riscv ~sparc x86"
+
+BDEPEND="
+ test? (
+ dev-python/zope-testing[${PYTHON_USEDEP}]
+ )
+"
+
+DOCS=( CHANGES.rst README.rst )
+
+distutils_enable_tests unittest
+
+python_prepare_all() {
+ # rdep is only needed for namespace
+ sed -i -e '/install_requires.*setuptools/d' setup.py || die
+ # use implicit namespace
+ sed -i -e '/namespace_packages/d' setup.py || die
+ # do not install README into site-packages
+ sed -e '/^ include_package_data/d' -i setup.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ "${EPYTHON}" -m unittest zc.lockfile.tests -v || die
+}
diff --git a/dev-python/zc-lockfile/zc-lockfile-2.0.ebuild b/dev-python/zc-lockfile/zc-lockfile-2.0.ebuild
deleted file mode 100644
index ba8a0dc845d..00000000000
--- a/dev-python/zc-lockfile/zc-lockfile-2.0.ebuild
+++ /dev/null
@@ -1,46 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-DISTUTILS_USE_SETUPTOOLS=rdepend
-PYTHON_COMPAT=( python3_{8..10} pypy3 )
-
-inherit distutils-r1
-
-MY_PN="${PN/-/.}"
-MY_P=${MY_PN}-${PV}
-
-DESCRIPTION="Basic inter-process locks"
-HOMEPAGE="https://pypi.org/project/zc.lockfile/"
-SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
-S="${WORKDIR}"/${MY_P}
-
-LICENSE="ZPL"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ~ppc64 ~riscv ~sparc x86"
-
-BDEPEND="test? ( dev-python/zope-testing[${PYTHON_USEDEP}] )"
-
-DOCS=( CHANGES.rst README.rst )
-
-distutils_enable_tests nose
-
-# Prevent incorrect installation of data file
-python_prepare_all() {
- sed -e '/^ include_package_data/d' -i setup.py || die
- distutils-r1_python_prepare_all
-}
-
-python_install() {
- distutils-r1_python_install
-
- python_moduleinto zc
- python_domodule src/zc/__init__.py
-}
-
-python_install_all() {
- distutils-r1_python_install_all
-
- find "${D}" -name '*.pth' -delete || die
-}