summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'dev-python')
-rw-r--r--dev-python/agate-sql/Manifest1
-rw-r--r--dev-python/agate-sql/agate-sql-0.5.6.ebuild58
-rw-r--r--dev-python/agate-sql/metadata.xml13
3 files changed, 72 insertions, 0 deletions
diff --git a/dev-python/agate-sql/Manifest b/dev-python/agate-sql/Manifest
new file mode 100644
index 00000000000..edde78265a3
--- /dev/null
+++ b/dev-python/agate-sql/Manifest
@@ -0,0 +1 @@
+DIST agate-sql-0.5.6.tar.gz 9091 BLAKE2B 9094a2bfb500422e7fe75d1c83182af698aa92942a305a69301d45d92f01960a7ffc7908f0eb2b66556a856be0f7388e222034428afd269d402488c6c05abd36 SHA512 b4234a86f8bcd5b22bcb1e18d0cec0ba21c8a3521e15f767886241e16285cbd296683f83bd366a82d1e549679b3712663adc080950dedb24a0e6db5b2541050a
diff --git a/dev-python/agate-sql/agate-sql-0.5.6.ebuild b/dev-python/agate-sql/agate-sql-0.5.6.ebuild
new file mode 100644
index 00000000000..9dbdd4b6469
--- /dev/null
+++ b/dev-python/agate-sql/agate-sql-0.5.6.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..9} )
+DISTUTILS_USE_SETUPTOOLS=bdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Adds SQL read/write support to agate."
+HOMEPAGE="https://github.com/wireservice/agate-sql https://pypi.org/project/agate-sql/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test +xml"
+RESTRICT="!test? ( test )"
+
+# Other packages have BDEPEND="test? ( dev-python/agate-sql[xml] )"
+AGATE_VERSION_DEP=">=dev-python/agate-1.5.0"
+TEST_AGAINST_RDEPEND="xml? ( ${AGATE_VERSION_DEP}[xml,${PYTHON_USEDEP}] )"
+RDEPEND="
+ ${AGATE_VERSION_DEP}[${PYTHON_USEDEP}]
+ >=dev-python/sqlalchemy-1.0.8[${PYTHON_USEDEP}]
+
+ ${TEST_AGAINST_RDEPEND}
+"
+BDEPEND="test? ( ${AGATE_VERSION_DEP}[xml,${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ local sed_args=(
+ -e "/crate/d"
+ -e "/nose/d"
+ -e "/geojson/d"
+ -e "/Sphinx/d"
+ -e "/sphinx_rtd_theme/d"
+ )
+
+ sed "${sed_args[@]}" -i setup.py agate_sql.egg-info/requires.txt || die
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ local pytest_args test_name xfails
+
+ xfails=(
+ tests/test_agatesql.py::TestSQL::test_to_sql_create_statement_with_dialects
+ tests/test_agatesql.py::TestSQL::test_to_sql_create_statement_with_schema
+ )
+
+ for test_name in "${xfails[@]}"; do
+ pytest_args+=(--deselect "${test_name}")
+ done
+
+ epytest "${pytest_args[@]}" || die
+}
diff --git a/dev-python/agate-sql/metadata.xml b/dev-python/agate-sql/metadata.xml
new file mode 100644
index 00000000000..a42278954df
--- /dev/null
+++ b/dev-python/agate-sql/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+ <email>zmedico@gentoo.org</email>
+ </maintainer>
+ <upstream>
+ <bugs-to>https://github.com/wireservice/agate-sql/issues</bugs-to>
+ <changelog>https://github.com/wireservice/agate-sql/blob/master/CHANGELOG.rst</changelog>
+ <remote-id type="pypi">agate-sql</remote-id>
+ <remote-id type="github">wireservice/agate-sql</remote-id>
+ </upstream>
+</pkgmetadata>