1 files changed, 46 insertions, 0 deletions
diff --git a/dev-ruby/psych/psych-2.2.2.ebuild b/dev-ruby/psych/psych-2.2.2.ebuild
new file mode 100644
index 000000000000..2726cf04a579
--- /dev/null
+++ b/dev-ruby/psych/psych-2.2.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+USE_RUBY="ruby20 ruby21 ruby22 ruby23"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.rdoc README.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="A libyaml wrapper for Ruby"
+HOMEPAGE="https://github.com/tenderlove/psych"
+SRC_URI="https://github.com/tenderlove/psych/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+DEPEND+=" >=dev-libs/libyaml-0.1.7"
+
+ruby_add_bdepend "test? ( dev-ruby/minitest:5 )"
+
+all_ruby_prepare() {
+	sed -i -e '1igem "minitest", "~>5.0"' test/psych/helper.rb || die
+	sed -i -e '/s.files/ s:^:#:' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext/${PN} extconf.rb || die
+}
+
+each_ruby_compile() {
+	emake V=1 -Cext/${PN}
+	cp ext/${PN}/${PN}$(get_modname) lib/ || die
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib:test:test/${PN}:. -e "Dir['test/psych/**/test_*.rb'].each {|f| require f}" || die
+}