1 files changed, 38 insertions, 0 deletions
diff --git a/dev-scheme/chibi/chibi-0.10.ebuild b/dev-scheme/chibi/chibi-0.10.ebuild
new file mode 100644
index 000000000000..189f61eb059f
--- /dev/null
+++ b/dev-scheme/chibi/chibi-0.10.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Minimal Scheme implementation for use as an extension language"
+HOMEPAGE="http://synthcode.com/scheme/chibi/"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ashinn/${PN}-scheme.git"
+else
+	SRC_URI="https://github.com/ashinn/${PN}-scheme/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-scheme-${PV}"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+
+src_configure() {
+	tc-export CC
+
+	export PREFIX="${EPREFIX}/usr"
+	export LIBDIR="${EPREFIX}/usr/$(get_libdir)"
+	export SOLIBDIR="${EPREFIX}/usr/$(get_libdir)"
+
+	# if ldconfig (stored in LDCONFIG variable) exists it is ran
+	export LDCONFIG="0"
+}
+
+src_install() {
+	default
+
+	dosym chibi-scheme /usr/bin/chibi
+}