1 files changed, 39 insertions, 0 deletions
diff --git a/dev-util/android-udev-rules/android-udev-rules-20230104.ebuild b/dev-util/android-udev-rules/android-udev-rules-20230104.ebuild
new file mode 100644
index 000000000000..12572552f91e
--- /dev/null
+++ b/dev-util/android-udev-rules/android-udev-rules-20230104.ebuild
@@ -0,0 +1,39 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit udev
+
+DESCRIPTION="Android udev rules list aimed to be the most comprehensive on the net"
+HOMEPAGE="https://github.com/M0Rf30/android-udev-rules"
+SRC_URI="https://github.com/M0Rf30/android-udev-rules/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	acct-group/android
+	virtual/udev
+"
+
+src_prepare() {
+	default
+
+	# Use the pre-existing android group
+	sed -i 's/GROUP="adbusers"/GROUP="android"/' 51-android.rules || die
+}
+
+src_install() {
+	udev_dorules 51-android.rules
+	einstalldocs
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}