summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'dev-util/dialog/dialog-1.3.20180621.ebuild')
-rw-r--r--dev-util/dialog/dialog-1.3.20180621.ebuild51
1 files changed, 51 insertions, 0 deletions
diff --git a/dev-util/dialog/dialog-1.3.20180621.ebuild b/dev-util/dialog/dialog-1.3.20180621.ebuild
new file mode 100644
index 00000000000..ffa55f6cd40
--- /dev/null
+++ b/dev-util/dialog/dialog-1.3.20180621.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils multilib versionator
+
+DIA_P="${PN}-$(replace_version_separator 2 '-')"
+DESCRIPTION="tool to display dialog boxes from a shell"
+HOMEPAGE="https://invisible-island.net/dialog/"
+SRC_URI="https://dev.gentoo.org/~jer/${DIA_P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0/15"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="examples minimal nls static-libs unicode"
+
+RDEPEND="
+ >=sys-libs/ncurses-5.2-r5:=[unicode?]
+"
+DEPEND="
+ ${RDEPEND}
+ nls? ( sys-devel/gettext )
+ !minimal? ( sys-devel/libtool )
+ !<=sys-freebsd/freebsd-contrib-8.9999
+"
+S=${WORKDIR}/${DIA_P}
+
+src_prepare() {
+ default
+ sed -i -e '/LIB_CREATE=/s:${CC}:& ${LDFLAGS}:g' configure || die
+ sed -i '/$(LIBTOOL_COMPILE)/s:$: $(LIBTOOL_OPTS):' makefile.in || die
+}
+
+src_configure() {
+ econf \
+ --disable-rpath-hack \
+ $(use_enable nls) \
+ $(use_with !minimal libtool) \
+ --with-libtool-opts=$(usex static-libs '' '-shared') \
+ --with-ncurses$(usex unicode w '')
+}
+
+src_install() {
+ use minimal && default || emake DESTDIR="${D}" install-full
+
+ use examples && dodoc -r samples
+
+ dodoc CHANGES README
+
+ prune_libtool_files
+}