1 files changed, 45 insertions, 0 deletions
diff --git a/dev-util/gcovr/gcovr-4.2.ebuild b/dev-util/gcovr/gcovr-4.2.ebuild
new file mode 100644
index 000000000000..5b264d4b384b
--- /dev/null
+++ b/dev-util/gcovr/gcovr-4.2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7,8} )
+DISTUTILS_IN_SOURCE_BUILD=1
+
+inherit distutils-r1
+
+DESCRIPTION="A Python script for summarizing gcov data"
+HOMEPAGE="https://github.com/gcovr/gcovr"
+SRC_URI="https://github.com/gcovr/gcovr/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+"
+BDEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/PyUtilib[${PYTHON_USEDEP}]
+		virtual/python-typing[${PYTHON_USEDEP}]
+	)
+"
+
+# tests fail on gcc newer than 5.8
+# https://github.com/gcovr/gcovr/issues/206
+RESTRICT="test"
+
+distutils_enable_tests pytest
+
+python_test() {
+	distutils_install_for_testing
+
+	local -x PATH="${TEST_DIR}/scripts:${PATH}" \
+		PYTHONPATH="${TEST_DIR}/lib"
+
+	pytest -vv gcovr || die "Tests fail with ${EPYTHON}"
+}