summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'games-engines/devilutionx/devilutionx-1.0.2.ebuild')
-rw-r--r--games-engines/devilutionx/devilutionx-1.0.2.ebuild78
1 files changed, 78 insertions, 0 deletions
diff --git a/games-engines/devilutionx/devilutionx-1.0.2.ebuild b/games-engines/devilutionx/devilutionx-1.0.2.ebuild
new file mode 100644
index 00000000000..829fcf1b68b
--- /dev/null
+++ b/games-engines/devilutionx/devilutionx-1.0.2.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# Sometimes build with ninja fails.
+# Please check occasionally if we can revert back to ninja.
+# Latest known issue:
+#
+#CMAKE_MAKEFILE_GENERATOR="emake"
+
+inherit cmake desktop
+
+DESCRIPTION="Diablo engine for modern operating systems"
+HOMEPAGE="https://github.com/diasurgical/devilutionX"
+if [[ "${PV}" == 9999 ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/diasurgical/devilutionX.git"
+else
+ SRC_URI="https://github.com/diasurgical/devilutionX/archive/${PV}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64 ~x86"
+ S="${WORKDIR}/devilutionX-${PV}"
+fi
+
+LICENSE="public-domain"
+SLOT="0"
+
+IUSE="debug lto"
+
+RDEPEND="
+ dev-libs/libsodium
+ media-fonts/sil-charis
+ media-libs/libsdl2[haptic]
+ media-libs/sdl2-mixer
+ media-libs/sdl2-ttf
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ virtual/pkgconfig
+"
+
+src_prepare() {
+ sed "/PROJECT_VERSION/s|@PROJECT_VERSION@|${PV}|" \
+ -i SourceS/config.h.in || die
+ sed 's/CharisSILB.ttf/CharisSIL-B.ttf/g' \
+ -i SourceX/DiabloUI/fonts.h || die
+ cmake_src_prepare
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DASAN="OFF"
+ -DDEBUG="$(usex debug)"
+ -DDIST="ON"
+ -DFASTER="OFF"
+ -DLTO="$(usex lto)"
+ -DUBSAN="OFF"
+ )
+ cmake_src_configure
+}
+
+src_install() {
+ dobin "${BUILD_DIR}/${PN}"
+
+ local size
+ for size in 32 48 ; do
+ newicon -s ${size} Packaging/resources/Diablo_${size}.png ${PN}.png
+ done
+ make_desktop_entry ${PN} "Diablo devolved" "/usr/share/icons/hicolor/48x48/apps/devilutionx.png"
+}
+
+pkg_postinst() {
+ einfo "In order to play the game you need to install the file"
+ einfo " diabdat.mpq"
+ einfo "from the original game CD into the following directory:"
+ einfo " \${HOME}/.local/share/diasurgical/devilution/"
+ einfo "and make sure it's writeable (chmod u+w)."
+}